random_access_list.mlw 7.23 KB
Newer Older
1 2

(** Random Access Lists.
3
    (Okasaki, "Purely Functional Data Structures", 10.1.2.)
4 5 6 7

    The code below uses polymorphic recursion (both in the logic
    and in the programs).

8
    Author: Jean-Christophe Filliâtre (CNRS)
9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24
 *)

module RandomAccessList

  use import int.Int
  use import int.ComputerDivision
  use import list.List
  use import list.Length
  use import list.Nth
  use import option.Option

  type ral 'a =
  | Empty
  | Zero    (ral ('a, 'a))
  | One  'a (ral ('a, 'a))

25
  function flatten (l: list ('a, 'a)) : list 'a
26 27 28 29 30
  = match l with
    | Nil -> Nil
    | Cons (x, y) l1 -> Cons x (Cons y (flatten l1))
    end

31
  let rec lemma length_flatten (l:list ('a, 'a))
32 33 34 35 36 37 38
    ensures { length (flatten l) = 2 * length l }
    variant { l }
  = match l with
    | Cons (_,_) q -> length_flatten q
    | Nil -> ()
    end

39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55
  function elements (l: ral 'a) : list 'a
    = match l with
      | Empty    -> Nil
      | Zero l1  -> flatten (elements l1)
      | One x l1 -> Cons x (flatten (elements l1))
      end

  let rec size (l: ral 'a) : int
    variant { l }
    ensures { result = length (elements l) }
  =
    match l with
    | Empty    -> 0
    | Zero  l1 ->     2 * size l1
    | One _ l1 -> 1 + 2 * size l1
    end

56
  let rec cons (x: 'a) (l: ral 'a) : ral 'a
57 58 59 60 61
    variant { l }
    ensures { elements result = Cons x (elements l) }
    = match l with
      | Empty    -> One x Empty
      | Zero l1  -> One x l1
62
      | One y l1 -> Zero (cons (x, y) l1)
63 64 65 66 67 68 69 70 71 72 73 74 75 76
      end

  let rec lemma nth_flatten (i: int) (l: list ('a, 'a))
    requires { 0 <= i < length l }
    variant  { l }
    ensures  { match nth i l with
               | None -> false
               | Some (x0, x1) -> Some x0 = nth (2 * i)     (flatten l) /\
                                  Some x1 = nth (2 * i + 1) (flatten l) end }
  = match l with
    | Nil -> ()
    | Cons _ r -> if i > 0 then nth_flatten (i-1) r
    end

77
  let rec lookup (i: int) (l: ral 'a) : 'a
78 79 80 81 82
    requires { 0 <= i < length (elements l) }
    variant  { i, l }
    ensures  { nth i (elements l) = Some result }
    = match l with
      | Empty    -> absurd
83 84
      | One x l1 -> if i = 0 then x else lookup (i-1) (Zero l1)
      | Zero l1  -> let (x0, x1) = lookup (div i 2) l1 in
85 86 87
                    if mod i 2 = 0 then x0 else x1
      end

88
  let rec tail (l: ral 'a) : ral 'a
89
    requires { elements l <> Nil }
90 91 92 93 94
    variant  { l }
    ensures  { match elements l with
               | Nil -> false
               | Cons _ l -> elements result = l
               end }
95 96 97
    = match l with
      | Empty    -> absurd
      | One _ l1 -> Zero l1
98
      | Zero  l1 -> let (_, x1) = lookup 0 l1 in One x1 (tail l1)
99 100
      end

101
  let rec update (i: int) (y: 'a) (l: ral 'a) : ral 'a
102 103 104 105 106 107 108 109 110 111 112 113 114
    requires { 0 <= i < length (elements l) }
    variant  { i, l}
    ensures  { nth i (elements result) = Some y}
    ensures  { forall j. 0 <= j < length (elements l) ->
               j <> i -> nth j (elements result) = nth j (elements l) }
    ensures  { length (elements result) = length (elements l) }
    ensures  { match result, l with
               | One _ _, One _ _ | Zero _, Zero _ -> true
               | _                                 -> false
               end }
    = match l with
      | Empty    -> absurd
      | One x l1 -> if i = 0 then One y l1 else
115
                    match update (i-1) y (Zero l1) with
116 117 118 119
                    | Empty | One _ _ -> absurd
                    | Zero l1         -> One x l1
                    end
      | Zero l1  ->
120 121
          let (x0, x1) = lookup (div i 2) l1 in
          let l1' = update (div i 2) (if mod i 2 = 0 then (y,x1) else (x0,y)) l1 in
122 123 124 125 126 127 128 129 130
            assert { forall j. 0 <= j < length (elements l) -> j <> i ->
               match nth (div j 2) (elements l1) with
               | None -> false
               | Some (x0,_) -> Some x0 = nth (2 * (div j 2)) (elements l)
               end
               && nth j (elements l) = nth j (elements (Zero l1')) };
          Zero l1'
      end

131
end
132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160

(** A straightforward encapsulation with a list ghost model
    (in anticipation of module refinement) *)

module RAL

  use import int.Int
  use import RandomAccessList as R
  use import list.List
  use import list.Length
  use import option.Option
  use import list.Nth

  type t 'a = { r: ral 'a; ghost l: list 'a }
    invariant { self.l = elements self.r }

  let empty () : t 'a
    ensures { result.l = Nil }
  =
    { r = Empty; l = Nil }

  let size (t: t 'a) : int
    ensures { result = length t.l }
  =
    size t.r

  let cons (x: 'a) (s: t 'a) : t 'a
    ensures { result.l = Cons x s.l }
  =
161
    { r = cons x s.r; l = Cons x s.l }
162

163
  let lookup (i: int) (s: t 'a) : 'a
164 165 166
    requires { 0 <= i < length s.l }
    ensures { Some result = nth i s.l }
  =
167
    lookup i s.r
168 169 170

end

171 172
(** Model using sequences instead of lists *)

173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205
module RandomAccessListWithSeq

  use import int.Int
  use import int.ComputerDivision
  use import seq.Seq

  type ral 'a =
  | Empty
  | Zero    (ral ('a, 'a))
  | One  'a (ral ('a, 'a))

  function flatten (s: seq ('a, 'a)) : seq 'a
    = create (2 * length s)
             (\ i: int. let (x0, x1) = s[div i 2] in
                        if mod i 2 = 0 then x0 else x1)

  function elements (l: ral 'a) : seq 'a
    = match l with
      | Empty    -> empty
      | Zero l1  -> flatten (elements l1)
      | One x l1 -> cons x (flatten (elements l1))
      end

  let rec size (l: ral 'a) : int
    variant { l }
    ensures { result = length (elements l) }
  =
    match l with
    | Empty    -> 0
    | Zero  l1 ->     2 * size l1
    | One _ l1 -> 1 + 2 * size l1
    end

206
  let rec cons (x: 'a) (l: ral 'a) : ral 'a
207 208 209 210 211
    variant { l }
    ensures { elements result == cons x (elements l) }
    = match l with
      | Empty    -> One x Empty
      | Zero l1  -> One x l1
212
      | One y l1 -> Zero (cons (x, y) l1)
213 214
      end

215
  let rec lookup (i: int) (l: ral 'a) : 'a
216 217 218 219 220
    requires { 0 <= i < length (elements l) }
    variant  { i, l }
    ensures  { (elements l)[i] = result }
    = match l with
      | Empty    -> absurd
221 222
      | One x l1 -> if i = 0 then x else lookup (i-1) (Zero l1)
      | Zero l1  -> let (x0, x1) = lookup (div i 2) l1 in
223 224 225
                    if mod i 2 = 0 then x0 else x1
      end

226
  let rec tail (l: ral 'a) : ral 'a
227 228 229
    requires { 0 < length (elements l) }
    variant  { l }
    ensures  { elements result == (elements l)[1 .. ] }
230 231 232
    = match l with
      | Empty    -> absurd
      | One _ l1 -> Zero l1
233
      | Zero  l1 -> let (_, x1) = lookup 0 l1 in One x1 (tail l1)
234 235
      end

236 237 238 239 240 241


   function setf (s: seq 'a) (i:int) (f: 'a -> 'a) : seq 'a =
     set s i (f s[i])


242 243 244 245
   function aux (i: int) (f: 'a -> 'a) : ('a,'a) -> ('a, 'a) =
     \ z. let (x,y) = z in if mod i 2 = 0 then (f x, y) else (x, f y)

   let rec fupdate (f: 'a -> 'a) (i: int) (l: ral 'a) : ral 'a
246 247
    requires { 0 <= i < length (elements l) }
    variant  { i, l}
248
    ensures  { elements result == setf (elements l) i f}
249 250
    = match l with
      | Empty    -> absurd
251
      | One x l1 -> if i = 0 then One (f x) l1 else
252 253
                    cons x (fupdate f (i-1) (Zero l1))
      | Zero l1  -> Zero (fupdate (aux i f) (div i 2) l1)
254 255
      end

256 257
   function f (y: 'a) : 'a -> 'a = \ _. y

258
   let update (i:int) (y: 'a) (l: ral 'a) : ral 'a
259 260
   requires { 0 <= i < length (elements l) }
   ensures  { elements result == set (elements l) i y}
261
   =  fupdate (f y) i  l
262

263
end