Commit c41443f9 authored by FAGES Francois's avatar FAGES Francois

fichier manquant dans brefs

parent ceec83a2
% Transmembrane inputs
MA(k25) for glucoseext => glucose.
MA(k26) for acetoneext => acetone.
% Glucose pathway to NADH
MA(k19) for G_1DH + NAD => Cia1.
MA(k20) for Cia1 => G_1DH + NAD.
MA(k21) for Cia1 + glucose => Cib1.
MA(k22) for Cib1 => Cia1 + glucose.
MA(k23) for Cib1 => Cfa1 + NADH.
MA(k24) for Cfa1 => G_1DH + gluconolacrone.
% Acetone pathway to Resorufin by consuming NADH
MA(k13) for ADH + NADH => Cia2.
MA(k14) for Cia2 => ADH + NADH.
MA(k15) for Cia2 + acetone => Cib2.
MA(k16) for Cib2 => Cia2 + acetone.
MA(k17) for Cib2 => Cfa2 + NAD.
MA(k18) for Cfa2 => ADH + isopropanol.
MA(k1) for HRP + H_2O_2 => Cia5.
MA(k2) for Cia5 => HRP + H_2O_2.
MA(k3) for Cia5 + resazurin => Cib5.
MA(k4) for Cib5 => Cia5 + resazurin.
MA(k5) for Cib5 => HRP + resorufin.
MA(k6) for HRP2 + NADH => Cf4.
MA(k7) for Cf4 => HRP2 + NADH.
MA(k8) for Cf4 => HRP2 + NADN.
MA(k9) for AO + isopropanol => Cf3.
MA(k10) for Cf3 => AO + isopropanol.
MA(k11) for Cf3 => Cio3 + H_2O_2.
MA(k12) for Cio3 => AO + HRP2.
% kinetic parameters
parameter(k1= 1.15157e-5).
parameter(k2=24).
parameter(k3=7.77313e-006).
parameter(k4=1).
parameter(k5=240).
parameter(k6=2.91492e-009).
parameter(k7=0.0009).
parameter(k8=0.009).
parameter(k9=5.82985e-008).
parameter(k10=15).
parameter(k11=150).
parameter(k12=10000).
parameter(k13=9.50049e-012).
parameter(k14=0.033).
parameter(k15=1.08824e-006).
parameter(k16=0.07).
parameter(k17=0.7).
parameter(k18=0.33).
parameter(k19=1.8077e-006).
parameter(k20=40).
parameter(k21=9.71641e-009).
parameter(k22=20).
parameter(k23=200).
parameter(k24=400).
parameter(k25=5e-3).
parameter(k26=1e-2).
% initial conditions
present(G_1DH, c).
present(ADH, a).
present(NADH, 31533).
present(NAD, 1576691971).
present(resazurin, 315338394).
present(HRP, 6565).
present(AO, b).
present(HRP2, 6565).
present(glucoseext, d).
present(acetoneext, e).
parameter(a=92078816, b=175012, c=2232595).
parameter(d=3e8, e=3e8).
% time horizon
option(time:3600).
Markdown is supported
0% or .
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment