Commit b918c291 authored by SOLIMAN Sylvain's avatar SOLIMAN Sylvain
Browse files

ASSB workshop

parent 00c28deb
%% Cell type:markdown id: tags:
# Minimal mitotic oscillator
after *[Albert Goldbeter 1991 PNAS](https://doi.org/10.1073/pnas.88.20.9107)*
<img src="oscillator.png" width=300>
François Fages and Sylvain Soliman, Inria Saclay Ile de France,
[ASSB workshop](https://assb.lri.fr/en/Abstracts/BIOCHAM.html), March 2018.
%% Cell type:code id: tags:
```
load(oscillator.bc).
```
%% Cell type:code id: tags:
```
list_model.
```
%% Cell type:code id: tags:
```
draw_reactions.
```
%% Cell type:markdown id: tags:
**Question:** _Do you think this system can oscillate? Does it have a_ **negative feedback loop**?
%% Cell type:code id: tags:
```
draw_influences.
```
%% Cell type:markdown id: tags:
**Question:** _Can you find which species are (mass-)conserved in this system?_
%% Cell type:code id: tags:
```
search_conservations.
```
%% Cell type:code id: tags:
```
list_ode.
```
%% Cell type:code id: tags:
```
numerical_simulation. plot.
```
%% Cell type:code id: tags:
```
plot(show:Cyclin, against:ProteaseP).
```
%% Cell type:markdown id: tags:
**Question:** _Can you find parameter values that increase or decrease Cyclin's period?_
%% Cell type:code id: tags:
```
%slider vi kd V2 K2
```
%% Cell type:code id: tags:
```
parameter(vi=0.025, kd=0.01, V2=1.5, K2=0.005).
```
%% Cell type:code id: tags:
```
numerical_simulation(method:ssa). plot.
```
%% Cell type:code id: tags:
```
numerical_simulation. plot.
```
%% Cell type:code id: tags:
```
validity_domain(amplitude(Cyclin,v)).
```
%% Cell type:code id: tags:
```
validity_domain(period(Cyclin,p)).
```
%% Cell type:code id: tags:
```
seed(0). search_parameters(period(Cyclin,p), [0<=vi<=1, 0<=V2<=2], [p -> 22]).
```
%% Cell type:code id: tags:
```
list_parameters.
```
%% Cell type:code id: tags:
```
numerical_simulation. plot.
```
%% Cell type:code id: tags:
```
validity_domain(period(Cyclin,p)).
```
%% Cell type:markdown id: tags:
---
Let's now have a closer look at the amplitude of the _Cyclin_…
%% Cell type:code id: tags:
```
plot(show: Cyclin).
```
%% Cell type:code id: tags:
```
validity_domain(amplitude(Cyclin, amp)).
```
%% Cell type:markdown id: tags:
**Question:** _Does this formula capture the amplitude between peaks?_
_Using the_ `local_minimum(Species, min)` _and_ `local_maximum(Species, max)` _constructs, can you write a pattern to capture that?_
%% Cell type:code id: tags:
```
ltl_pattern(peak_amplitude(Species, Amplitude) =
exists(min, exists(max, local_minimum(Species, min) /\ local_maximum(Species, max) /\ Amplitude <= max - min))).
```
%% Cell type:code id: tags:
```
validity_domain(peak_amplitude(Cyclin, amp)).
```
%% Cell type:code id: tags:
```
seed(0). search_parameters(peak_amplitude(Cyclin, amp), [0<=vi<=1, 0<=V2<=2], [amp -> 0.8]).
```
%% Cell type:code id: tags:
```
option(show: {Cyclin, Protease, Kinase}).
```
%% Cell type:code id: tags:
```
numerical_simulation. plot.
```
%% Cell type:code id: tags:
```
validity_domain(peak_amplitude(Cyclin, amp)).
```
%% Cell type:code id: tags:
```
robustness(peak_amplitude(Cyclin, amp), [vi, V2], [amp -> 0.8]).
```
%% Cell type:code id: tags:
```
seed(0). search_parameters(peak_amplitude(Cyclin, amp), [0<=vi<=1, 0<=V2<=2], [amp -> 0.8], cmaes_stop_fitness: -0.1).
```
%% Cell type:code id: tags:
```
numerical_simulation. plot.
```
%% Cell type:code id: tags:
```
validity_domain(peak_amplitude(Cyclin, amp)).
```
%% Cell type:code id: tags:
```
robustness(peak_amplitude(Cyclin, amp), [vi, V2], [amp -> 0.8]).
```
%% Cell type:code id: tags:
```
validity_domain(period(Cyclin, p)).
```
%% Cell type:code id: tags:
```
```
Markdown is supported
0% or .
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment