commandline.pl

:- module(
  commandline,
  [
    do_arguments/0
  ]
).


do_arguments :-
  current_prolog_flag(argv, Argv),
  do_arguments(Argv).


:- dynamic(file/1).


do_arguments(Argv) :-
  retractall(file(_)),
  parse_arguments(Argv),
  load_files.


load_files :-
  \+ (
    file(File),
    \+ (
      load(File)
    )
  ).


parse_arguments([]).

parse_arguments([Arg | Argv]) :-
  (
    Arg = '--'
  ->
    add_files(Argv)
  ;
    atom_concat('--', _, Arg)
  ->
    (
      option(_, Arg, Argv, ArgTail)
    ->
      parse_arguments(ArgTail)
    ;
      throw(error(unknown_option(Arg)))
    )
  ;
    add_file(Arg),
    parse_arguments(Argv)
  ).


option('', '--trace', Arg, Arg) :-
  leash(-all),
  trace.

option('', '--generate-doc', Arg, Arg) :-
  generate_doc,
  quit.

option('', '--version', Arg, Arg) :-
   quit.

option('', '--jupyter', Arg, Arg) :-
  set_counter(plot_png, 0),
  set_counter(graph_svg, 0),
  set_plot_driver(gnu_plot_png),
  set_image_viewer_driver(img_tag),
  set_draw_graph_driver(graph_svg).


add_files(Files) :-
  \+ (
    member(File, Files),
    \+ (
      add_file(File)
    )
  ).


add_file(File) :-
  assertz(file(File)).