Initial commit.

.gitignore

+*~
+,*
+/site

about.md

+title: About
+---
+
+Guix-HPC is a joint software development project between
+[Inria](https://www.inria.fr/en), the
+[Max Delbrück Center for Molecular Medicine (MDC)](https://www.mdc-berlin.de/),
+and [UMC Utrecht](http://www.umcutrecht.nl/en/-1).  Guix-HPC an effort
+to optimize [GNU Guix](https://gnu.org/s/guix) for reproducible
+scientific workflows in high-performance computing (HPC).

guix-hpc.scm

+;;; This module is part of Guix-HPC and is licensed under the same terms,
+;;; those of the GNU GPL version 3 or (at your option) any later version.
+;;;
+;;; Copyright © 2017 Inria
+
+(define-module (guix-hpc)
+  #:use-module (haunt page)
+  #:use-module (sxml simple)
+  #:use-module (haunt reader)
+  #:use-module (haunt reader commonmark)
+  #:export (static-pages))
+
+(define %cwd
+  (and=> (assq-ref (current-source-location) 'filename)
+         dirname))
+
+(define read-markdown
+  (reader-proc commonmark-reader))
+
+(define (about-page)
+  (read-markdown (string-append %cwd "/about.md")))
+
+(define (static-pages)
+  (list (make-page "about.html" (about-page) sxml->xml)))

guix.scm

+;;; This module is part of Guix-HPC and is licensed under the same terms,
+;;; those of the GNU GPL version 3 or (at your option) any later version.
+;;;
+;;; Copyright © 2017 Inria
+
+;; Run 'guix build -f guix.scm' to build the web site.
+
+(use-modules (guix) (gnu)
+             (guix modules)
+             (guix git-download))
+
+(define haunt
+  (specification->package "haunt"))
+
+(define guile-commonmark
+  (specification->package "guile-commonmark"))
+
+(define source
+  (local-file "." "guix-hpc-web"
+              #:recursive? #t
+              #:select? (git-predicate ".")))
+
+(with-imported-modules (source-module-closure
+                        '((guix build utils)))
+  #~(begin
+      (use-modules (guix build utils))
+
+      (copy-recursively #$source ".")
+
+      ;; For Haunt.
+      (setenv "GUILE_LOAD_PATH"
+              #+(file-append guile-commonmark
+                             "/share/guile/site/2.2"))
+
+      ;; So we can read/write UTF-8 files.
+      (setenv "GUIX_LOCPATH"
+              #+(file-append (specification->package "glibc-utf8-locales")
+                             "/lib/locale"))
+      (setenv "LC_ALL" "en_US.utf8")
+
+      (and (zero? (system* #+(file-append haunt "/bin/haunt")
+                           "build"))
+           (begin
+             (mkdir-p #$output)
+             (copy-recursively "site" #$output)))))

haunt.scm

+;;; This module is part of Guix-HPC and is licensed under the same terms,
+;;; those of the GNU GPL version 3 or (at your option) any later version.
+;;;
+;;; Copyright © 2017 Inria
+
+;; This is a build file for Haunt.  Run 'haunt build' to build the web site,
+;; and 'haunt serve' to serve it locally.  Alternatively, you can run
+;; 'guix build -f guix.scm' to have everything built in the store.
+(use-modules (haunt site)
+             (haunt reader)
+             (haunt reader commonmark)
+             (haunt page)
+             (haunt html)
+             (haunt utils)
+             (haunt builder assets)
+             (haunt builder blog)
+             (haunt builder atom)
+             (ice-9 match)
+             (srfi srfi-1)
+             (guix-hpc))
+
+(define %local-test?
+  ;; True when we're testing locally, as opposed to producing things to
+  ;; install to gnu.org.
+  (or (getenv "WEB_SITE_LOCAL")
+      (member "serve" (command-line))))           ;'haunt serve' command
+
+(when %local-test?
+  ;; The URLs produced in these pages are only meant for local consumption.
+  (format #t "~%Producing Web pages for local tests *only*!~%~%")
+  (current-url-root ""))
+
+(site #:title
+      "Guix HPC — Reproducible software deployment for high-performance computing"
+      #:domain "//hpc.guixsd.org/"
+      #:default-metadata
+      '((author . "Guix-HPC Contributors")
+        (email  . "guix-devel@gnu.org"))
+      #:readers (list commonmark-reader)
+      #:builders
+      (cons* (blog ;; #:theme %news-haunt-theme
+              ;; #:prefix "news"
+              )
+
+             ;; Apparently the <link> tags of Atom entries must be absolute URLs,
+             ;; hence this #:blog-prefix.
+             (atom-feed #:file-name "news/feed.xml"
+                        #:blog-prefix "https://hpc.guixsd.org")
+
+             ;; (static-directory "static")
+
+             (map (lambda (page)
+                    (lambda (site posts)
+                      page))
+                  (static-pages))))

posts/guix-hpc-debuts.md

+title: Guix-HPC debut!
+author: Ludovic Courtès
+date: 2017-05-15 14:00
+---
+
+This post marks the debut of Guix-HPC, an effort to optimize
+[GNU Guix](https://gnu.org/s/guix) for reproducible scientific workflows
+in high-performance computing (HPC).