FindBLAS.cmake 25.6 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744
# - Find BLAS library
# This module finds an installed fortran library that implements the BLAS
# linear-algebra interface (see http://www.netlib.org/blas/).
# The list of libraries searched for is taken
# from the autoconf macro file, acx_blas.m4 (distributed at
# http://ac-archive.sourceforge.net/ac-archive/acx_blas.html).
#
# This module sets the following variables:
#  BLAS_FOUND - set to true if a library implementing the BLAS interface
#    is found
#  BLAS_LINKER_FLAGS - uncached list of required linker flags (excluding -l
#    and -L).
#  BLAS_LIBRARIES - uncached list of libraries (using full path name) to
#    link against to use BLAS
#  BLAS95_LIBRARIES - uncached list of libraries (using full path name)
#    to link against to use BLAS95 interface
#  BLAS95_FOUND - set to true if a library implementing the BLAS f95 interface
#    is found
#  BLA_STATIC  if set on this determines what kind of linkage we do (static)
#  BLA_VENDOR  if set checks only the specified vendor, if not set checks
#     all the possibilities
#  BLA_F95     if set on tries to find the f95 interfaces for BLAS/LAPACK
# The user can give specific paths where to find the libraries adding cmake 
# options at configure (ex: cmake path/to/project -DBLAS_DIR=path/to/blas):
#  BLAS_DIR            - Where to find the base directory of blas
#  BLAS_INCDIR         - Where to find the header files
#  BLAS_LIBDIR         - Where to find the library files
##########
### List of vendors (BLA_VENDOR) valid in this module
########## List of vendors (BLA_VENDOR) valid in this module
##  Goto,ATLAS PhiPACK,CXML,DXML,SunPerf,SCSL,SGIMATH,IBMESSL,Intel10_32 (intel mkl v10 32 bit),Intel10_64lp (intel mkl v10 64 bit,lp thread model, lp64 model),
##  Intel10_64lp_seq (intel mkl v10 64 bit,sequential code, lp64 model),
##  Intel( older versions of mkl 32 and 64 bit), ACML,ACML_MP,ACML_GPU,Apple, NAS, Generic
# C/CXX should be enabled to use Intel mkl

#=============================================================================
# Copyright 2007-2009 Kitware, Inc.
#
# Distributed under the OSI-approved BSD License (the "License");
# see accompanying file Copyright.txt for details.
#
# This software is distributed WITHOUT ANY WARRANTY; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
# See the License for more information.
#=============================================================================
# (To distribute this file outside of CMake, substitute the full
#  License text for the above reference.)

# Some macros to print status when search for headers and libs
# PrintFindStatus.cmake is in cmake_modules/morse/find directory of magmamorse
include(PrintFindStatus)
option(BLAS_VERBOSE "Print some additional information during BLAS 
libraries detection" OFF)

include(CheckFunctionExists)
include(CheckFortranFunctionExists)

set(_blas_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES})

# Check the language being used
get_property( _LANGUAGES_ GLOBAL PROPERTY ENABLED_LANGUAGES )
if( _LANGUAGES_ MATCHES Fortran )
    set( _CHECK_FORTRAN TRUE )
elseif( (_LANGUAGES_ MATCHES C) OR (_LANGUAGES_ MATCHES CXX) )
    set( _CHECK_FORTRAN FALSE )
else()
    if(BLAS_FIND_REQUIRED)
        message(FATAL_ERROR "FindBLAS requires Fortran, C, or C++ to be enabled.")
    else()
        message(STATUS "Looking for BLAS... - NOT found (Unsupported languages)")
        return()
    endif()
endif()

macro(Check_Fortran_Libraries LIBRARIES _prefix _name _flags _list _thread)
# This macro checks for the existence of the combination of fortran libraries
# given by _list.  If the combination is found, this macro checks (using the
# Check_Fortran_Function_Exists macro) whether can link against that library
# combination using the name of a routine given by _name using the linker
# flags given by _flags.  If the combination of libraries is found and passes
# the link test, LIBRARIES is set to the list of complete library paths that
# have been found.  Otherwise, LIBRARIES is set to FALSE.

# N.B. _prefix is the prefix applied to the names of all cached variables that
# are generated internally and marked advanced by this macro.

    set(_libdir ${ARGN})
    
    set(_libraries_work TRUE)
    set(${LIBRARIES} ${_flags})
    set(_combined_name)
    if (NOT _libdir)
        if (BLAS_DIR)
            list(APPEND _libdir "${BLAS_DIR}")
            list(APPEND _libdir "${BLAS_DIR}/lib")
            list(APPEND _libdir "${BLAS_DIR}/lib32")
            list(APPEND _libdir "${BLAS_DIR}/lib64")
            list(APPEND _libdir "${BLAS_DIR}/lib/ia32")
            list(APPEND _libdir "${BLAS_DIR}/lib/intel64")
        endif ()
        if (BLAS_LIBDIR)
            list(APPEND _libdir "${BLAS_LIBDIR}")
        endif ()
        if (WIN32)
            string(REPLACE ":" ";" _libdir2 "$ENV{LIB}")
        elseif (APPLE)
            string(REPLACE ":" ";" _libdir2 "$ENV{DYLD_LIBRARY_PATH}")
        else ()
            string(REPLACE ":" ";" _libdir2 "$ENV{LD_LIBRARY_PATH}")
        endif ()
        list(APPEND _libdir "${_libdir2}")
        list(APPEND _libdir "${CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES}")
        list(APPEND _libdir "${CMAKE_C_IMPLICIT_LINK_DIRECTORIES}")
    endif ()
    
    if (BLAS_VERBOSE)
        message("${Cyan}Try to find BLAS libraries: ${_list}")
    endif ()
    
    foreach(_library ${_list})
        set(_combined_name ${_combined_name}_${_library})
    
        if(_libraries_work)
            if (BLA_STATIC)
                if (WIN32)
                    set(CMAKE_FIND_LIBRARY_SUFFIXES .lib ${CMAKE_FIND_LIBRARY_SUFFIXES})
                endif ()
                if (APPLE)
                    set(CMAKE_FIND_LIBRARY_SUFFIXES .lib ${CMAKE_FIND_LIBRARY_SUFFIXES})
                else ()
                    set(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
                endif ()
            else ()
                if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
                    # for ubuntu's libblas3gf and liblapack3gf packages
                    set(CMAKE_FIND_LIBRARY_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES} .so.3gf)
                endif ()
            endif ()
            find_library(${_prefix}_${_library}_LIBRARY
                NAMES ${_library}
                HINTS ${_libdir}
              )
            mark_as_advanced(${_prefix}_${_library}_LIBRARY)
            # Print status if not found
            # -------------------------
            if (NOT ${_prefix}_${_library}_LIBRARY AND BLAS_VERBOSE)
                Print_Find_Library_Blas_Status(blas ${_library} ${_libdir})
            endif ()
            set(${LIBRARIES} ${${LIBRARIES}} ${${_prefix}_${_library}_LIBRARY})
            set(_libraries_work ${${_prefix}_${_library}_LIBRARY})
        endif(_libraries_work)
    endforeach(_library ${_list})  
    
    if(_libraries_work) 
        # Test this combination of libraries.
        set(CMAKE_REQUIRED_LIBRARIES ${_flags} ${${LIBRARIES}} ${_thread})
        if (BLAS_VERBOSE)
            message("${Cyan}BLAS libs found. Try to compile symbol ${_name} with"
                    "following libraries: ${CMAKE_REQUIRED_LIBRARIES}")
        endif ()             
        if (_CHECK_FORTRAN)
            check_fortran_function_exists("${_name}" ${_prefix}${_combined_name}_WORKS)
        else()
            check_function_exists("${_name}_" ${_prefix}${_combined_name}_WORKS)
        endif()
        mark_as_advanced(${_prefix}${_combined_name}_WORKS)
        set(_libraries_work ${${_prefix}${_combined_name}_WORKS})
        # Print status if not found
        # -------------------------
        if (NOT _libraries_work AND BLAS_VERBOSE)
            Print_Find_Library_Blas_CheckFunc_Status(${_name} ${CMAKE_REQUIRED_LIBRARIES})
        endif ()
        set(CMAKE_REQUIRED_LIBRARIES)
    endif()
    
    if(NOT _libraries_work)
        set(${LIBRARIES} FALSE)
    endif()

# message("DEBUG: ${LIBRARIES} = ${${LIBRARIES}}")

endmacro(Check_Fortran_Libraries)


set(BLAS_LINKER_FLAGS)
set(BLAS_LIBRARIES)
set(BLAS95_LIBRARIES)
if ($ENV{BLA_VENDOR} MATCHES ".+")
    set(BLA_VENDOR $ENV{BLA_VENDOR})
else ()
    if(NOT BLA_VENDOR)
        set(BLA_VENDOR "All")
    endif()
endif ()

#BLAS in intel mkl 10 library? (em64t 64bit)
if (BLA_VENDOR MATCHES "Intel*" OR BLA_VENDOR STREQUAL "All")
    
    if (NOT WIN32)
        set(LM "-lm")
    endif ()
    if (_LANGUAGES_ MATCHES C OR _LANGUAGES_ MATCHES CXX)
        if(BLAS_FIND_QUIETLY OR NOT BLAS_FIND_REQUIRED)
            find_package(Threads)
        else()
            find_package(Threads REQUIRED)
        endif()

        set(BLAS_SEARCH_LIBS "")
        
        set(additional_flags)
        if(NOT WIN32)
            if (CMAKE_Fortran_COMPILER MATCHES ".+f95.*" OR
                CMAKE_Fortran_COMPILER MATCHES ".+gfortran.*")
                list(APPEND additional_flags "-Wl,--no-as-needed")      
            endif ()
        endif()
           

        if(BLA_F95)
        
            set(BLAS_mkl_SEARCH_SYMBOL SGEMM)
            set(_LIBRARIES BLAS95_LIBRARIES)
            if (WIN32)
                list(APPEND BLAS_SEARCH_LIBS
                    "mkl_blas95 mkl_intel_c mkl_intel_thread mkl_core libguide40")
            else ()         
                if (BLA_VENDOR STREQUAL "Intel10_32" OR BLA_VENDOR STREQUAL "All")
                    list(APPEND BLAS_SEARCH_LIBS
                        "mkl_blas95 mkl_intel mkl_intel_thread mkl_core guide")
                endif ()
                if (BLA_VENDOR STREQUAL "Intel10_64lp" OR BLA_VENDOR STREQUAL "All")
                    # old version
                    list(APPEND BLAS_SEARCH_LIBS
                        "mkl_blas95 mkl_intel_lp64 mkl_intel_thread mkl_core guide")

                    # mkl >= 10.3
                    if (CMAKE_C_COMPILER MATCHES ".+gcc.*")
                        list(APPEND BLAS_SEARCH_LIBS
                            "mkl_blas95_lp64 mkl_intel_lp64 mkl_gnu_thread mkl_core gomp")
                    else ()
                        list(APPEND BLAS_SEARCH_LIBS
                            "mkl_blas95_lp64 mkl_intel_lp64 mkl_intel_thread mkl_core iomp5")
                    endif ()
                endif ()
            endif ()
            if (BLA_VENDOR STREQUAL "Intel10_64lp_seq" OR BLA_VENDOR STREQUAL "All")
                list(APPEND BLAS_SEARCH_LIBS
                    "mkl_blas95_lp64 mkl_intel_lp64 mkl_sequential mkl_core")
            endif ()
            
        else (BLA_F95)
        
            set(BLAS_mkl_SEARCH_SYMBOL sgemm)
            set(_LIBRARIES BLAS_LIBRARIES)
            if (WIN32)
                list(APPEND BLAS_SEARCH_LIBS
                    "mkl_c_dll mkl_intel_thread_dll mkl_core_dll libguide40")
            else (WIN32)
#                set(additional_flags)
#                if (CMAKE_Fortran_COMPILER MATCHES ".+gfortran.*")
#                    list(APPEND additional_flags "-Wl,--no-as-needed")      
#                endif ()

                if (BLA_VENDOR STREQUAL "Intel10_32" OR BLA_VENDOR STREQUAL "All")
                    list(APPEND BLAS_SEARCH_LIBS
                        "mkl_intel mkl_intel_thread mkl_core guide")
                endif ()
      
                if (BLA_VENDOR STREQUAL "Intel10_64lp" OR BLA_VENDOR STREQUAL "All")
                    # old version
                    list(APPEND BLAS_SEARCH_LIBS
                        "mkl_intel_lp64 mkl_intel_thread mkl_core guide")
                    # mkl >= 10.3
                    if (CMAKE_C_COMPILER MATCHES ".+gcc.*")
                        list(APPEND BLAS_SEARCH_LIBS
                            "mkl_intel_lp64 mkl_gnu_thread mkl_core gomp")
                    else ()
                        list(APPEND BLAS_SEARCH_LIBS
                            "mkl_intel_lp64 mkl_intel_thread mkl_core iomp5")
                    endif ()
                endif ()

                #older vesions of intel mkl libs
                if (BLA_VENDOR STREQUAL "Intel" OR BLA_VENDOR STREQUAL "All")
                    list(APPEND BLAS_SEARCH_LIBS
                        "mkl")
                    list(APPEND BLAS_SEARCH_LIBS
                        "mkl_ia32")
                    list(APPEND BLAS_SEARCH_LIBS
                        "mkl_em64t")
                endif ()
            endif (WIN32)
            
            if (BLA_VENDOR STREQUAL "Intel10_64lp_seq" OR BLA_VENDOR STREQUAL "All")
                list(APPEND BLAS_SEARCH_LIBS
                    "mkl_intel_lp64 mkl_sequential mkl_core")
            endif ()
            
        endif (BLA_F95)

        foreach (IT ${BLAS_SEARCH_LIBS})
            string(REPLACE " " ";" SEARCH_LIBS ${IT})
            check_fortran_libraries(
            ${_LIBRARIES}
            BLAS
            ${BLAS_mkl_SEARCH_SYMBOL}
            "${additional_flags}"
            "${SEARCH_LIBS}"
            "${CMAKE_THREAD_LIBS_INIT};${LM}"
            )
        endforeach ()

    endif (_LANGUAGES_ MATCHES C OR _LANGUAGES_ MATCHES CXX)
    
endif (BLA_VENDOR MATCHES "Intel*" OR BLA_VENDOR STREQUAL "All")


if (BLA_VENDOR STREQUAL "Goto" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        # gotoblas (http://www.tacc.utexas.edu/tacc-projects/gotoblas2)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "goto2"
        ""
        )
    endif()
    
endif (BLA_VENDOR STREQUAL "Goto" OR BLA_VENDOR STREQUAL "All")


if (BLA_VENDOR STREQUAL "ATLAS" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        # BLAS in ATLAS library? (http://math-atlas.sourceforge.net/)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        dgemm
        ""
        "f77blas;atlas"
        ""
        )
    endif()
    
endif (BLA_VENDOR STREQUAL "ATLAS" OR BLA_VENDOR STREQUAL "All")


# BLAS in PhiPACK libraries? (requires generic BLAS lib, too)
if (BLA_VENDOR STREQUAL "PhiPACK" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "sgemm;dgemm;blas"
        ""
        )
    endif()
    
endif (BLA_VENDOR STREQUAL "PhiPACK" OR BLA_VENDOR STREQUAL "All")


# BLAS in Alpha CXML library?
if (BLA_VENDOR STREQUAL "CXML" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "cxml"
        ""
        )    
    endif()

endif (BLA_VENDOR STREQUAL "CXML" OR BLA_VENDOR STREQUAL "All")


# BLAS in Alpha DXML library? (now called CXML, see above)
if (BLA_VENDOR STREQUAL "DXML" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "dxml"
        ""
        )
    endif()

endif (BLA_VENDOR STREQUAL "DXML" OR BLA_VENDOR STREQUAL "All")


# BLAS in Sun Performance library?
if (BLA_VENDOR STREQUAL "SunPerf" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        "-xlic_lib=sunperf"
        "sunperf;sunmath"
        ""
        )
        if(BLAS_LIBRARIES)
            set(BLAS_LINKER_FLAGS "-xlic_lib=sunperf")
        endif()
    endif()
    
endif ()


# BLAS in SCSL library?  (SGI/Cray Scientific Library)
if (BLA_VENDOR STREQUAL "SCSL" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "scsl"
        ""
        )
    endif()
    
endif ()


# BLAS in SGIMATH library?
if (BLA_VENDOR STREQUAL "SGIMATH" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "complib.sgimath"
        ""
        )
    endif()
    
endif ()


# BLAS in IBM ESSL library? (requires generic BLAS lib, too)
if (BLA_VENDOR STREQUAL "IBMESSL" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "essl;blas"
        ""
        )
    endif()
    
endif ()


#BLAS in acml library?
if (BLA_VENDOR MATCHES "ACML.*" OR BLA_VENDOR STREQUAL "All")

    if( ((BLA_VENDOR STREQUAL "ACML") AND (NOT BLAS_ACML_LIB_DIRS)) OR
        ((BLA_VENDOR STREQUAL "ACML_MP") AND (NOT BLAS_ACML_MP_LIB_DIRS)) OR
        ((BLA_VENDOR STREQUAL "ACML_GPU") AND (NOT BLAS_ACML_GPU_LIB_DIRS)))
      
        # try to find acml in "standard" paths
        if( WIN32 )
            file( GLOB _ACML_ROOT "C:/AMD/acml*/ACML-EULA.txt" )
        else()
            file( GLOB _ACML_ROOT "/opt/acml*/ACML-EULA.txt" )
        endif()
        if( WIN32 )
            file( GLOB _ACML_GPU_ROOT "C:/AMD/acml*/GPGPUexamples" )
        else()
            file( GLOB _ACML_GPU_ROOT "/opt/acml*/GPGPUexamples" )
        endif()
        list(GET _ACML_ROOT 0 _ACML_ROOT)
        list(GET _ACML_GPU_ROOT 0 _ACML_GPU_ROOT)
        
        if( _ACML_ROOT )
        
            get_filename_component( _ACML_ROOT ${_ACML_ROOT} PATH )
            if( SIZEOF_INTEGER EQUAL 8 )
                set( _ACML_PATH_SUFFIX "_int64" )
            else()
                set( _ACML_PATH_SUFFIX "" )
            endif()
            if( CMAKE_Fortran_COMPILER_ID STREQUAL "Intel" )
                set( _ACML_COMPILER32 "ifort32" )
                set( _ACML_COMPILER64 "ifort64" )
            elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "SunPro" )
                set( _ACML_COMPILER32 "sun32" )
                set( _ACML_COMPILER64 "sun64" )
            elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "PGI" )
                set( _ACML_COMPILER32 "pgi32" )
                if( WIN32 )
                    set( _ACML_COMPILER64 "win64" )
                else()
                    set( _ACML_COMPILER64 "pgi64" )
                endif()
            elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "Open64" )
                # 32 bit builds not supported on Open64 but for code simplicity
                # We'll just use the same directory twice
                set( _ACML_COMPILER32 "open64_64" )
                set( _ACML_COMPILER64 "open64_64" )
            elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "NAG" )
                set( _ACML_COMPILER32 "nag32" )
                set( _ACML_COMPILER64 "nag64" )
            else()
                set( _ACML_COMPILER32 "gfortran32" )
                set( _ACML_COMPILER64 "gfortran64" )
            endif()

            if( BLA_VENDOR STREQUAL "ACML_MP" )
                set(_ACML_MP_LIB_DIRS
                    "${_ACML_ROOT}/${_ACML_COMPILER32}_mp${_ACML_PATH_SUFFIX}/lib"
                    "${_ACML_ROOT}/${_ACML_COMPILER64}_mp${_ACML_PATH_SUFFIX}/lib" )
            else()
                set(_ACML_LIB_DIRS
                    "${_ACML_ROOT}/${_ACML_COMPILER32}${_ACML_PATH_SUFFIX}/lib"
                    "${_ACML_ROOT}/${_ACML_COMPILER64}${_ACML_PATH_SUFFIX}/lib" )
            endif()
            
        endif(_ACML_ROOT)
        
    elseif(BLAS_${BLA_VENDOR}_LIB_DIRS)
    
        set(_${BLA_VENDOR}_LIB_DIRS ${BLAS_${BLA_VENDOR}_LIB_DIRS})
        
    endif()

    if( BLA_VENDOR STREQUAL "ACML_MP" )
        foreach( BLAS_ACML_MP_LIB_DIRS ${_ACML_MP_LIB_DIRS})
            check_fortran_libraries (
            BLAS_LIBRARIES
            BLAS
            sgemm
            "" "acml_mp;acml_mv" "" ${BLAS_ACML_MP_LIB_DIRS}
            )
            if( BLAS_LIBRARIES )
                break()
            endif()
        endforeach()
    elseif( BLA_VENDOR STREQUAL "ACML_GPU" )
        foreach( BLAS_ACML_GPU_LIB_DIRS ${_ACML_GPU_LIB_DIRS})
            check_fortran_libraries (
            BLAS_LIBRARIES
            BLAS
            sgemm
            "" "acml;acml_mv;CALBLAS" "" ${BLAS_ACML_GPU_LIB_DIRS}
            )
            if( BLAS_LIBRARIES )
                break()
            endif()
        endforeach()
    else()
        foreach( BLAS_ACML_LIB_DIRS ${_ACML_LIB_DIRS} )
            check_fortran_libraries (
            BLAS_LIBRARIES
            BLAS
            sgemm
            "" "acml;acml_mv" "" ${BLAS_ACML_LIB_DIRS}
            )
            if( BLAS_LIBRARIES )
                break()
            endif()
        endforeach()
    endif()

    # Either acml or acml_mp should be in LD_LIBRARY_PATH but not both
    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "acml;acml_mv"
        ""
        )
    endif()
    
    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "acml_mp;acml_mv"
        ""
        )
    endif()
    
    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "acml;acml_mv;CALBLAS"
        ""
        )
    endif()
 
endif (BLA_VENDOR MATCHES "ACML.*" OR BLA_VENDOR STREQUAL "All") # ACML


# Apple BLAS library?
if (BLA_VENDOR STREQUAL "Apple" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        dgemm
        ""
        "Accelerate"
        ""
        )
    endif()
    
endif (BLA_VENDOR STREQUAL "Apple" OR BLA_VENDOR STREQUAL "All")


if (BLA_VENDOR STREQUAL "NAS" OR BLA_VENDOR STREQUAL "All")

    if ( NOT BLAS_LIBRARIES )
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        dgemm
        ""
        "vecLib"
        ""
        )
    endif ()
    
endif (BLA_VENDOR STREQUAL "NAS" OR BLA_VENDOR STREQUAL "All")


# Generic BLAS library?
if (BLA_VENDOR STREQUAL "Generic" OR BLA_VENDOR STREQUAL "All")

    if(NOT BLAS_LIBRARIES)
        check_fortran_libraries(
        BLAS_LIBRARIES
        BLAS
        sgemm
        ""
        "blas"
        ""
        )
    endif()
    
endif (BLA_VENDOR STREQUAL "Generic" OR BLA_VENDOR STREQUAL "All")


if(BLA_F95)

    if(BLAS95_LIBRARIES)
       set(BLAS95_FOUND TRUE)
    else()
       set(BLAS95_FOUND FALSE)
    endif()

    if(NOT BLAS_FIND_QUIETLY)
        if(BLAS95_FOUND)
            message(STATUS "A library with BLAS95 API found.")
            message(STATUS "BLAS_LIBRARIES ${BLAS_LIBRARIES}")
        else(BLAS95_FOUND)
            message(WARNING "BLA_VENDOR has been set to ${BLA_VENDOR} but blas 95 libraries could not be found or check of symbols failed."
                "\nPlease indicate where to find blas libraries. You have three options:\n"
                "- Option 1: Provide the root directory of BLAS library with cmake option: -DBLAS_DIR=your/path/to/blas\n"
                "- Option 2: Provide the directory where to find BLAS libraries with cmake option: -DBLAS_LIBDIR=your/path/to/blas/libs\n"
                "- Option 3: Update your environment variable (Linux: LD_LIBRARY_PATH, Windows: LIB, Mac: DYLD_LIBRARY_PATH)\n"                
                "\nTo follow libraries detection more precisely you can activate a verbose mode with -DBLAS_VERBOSE=ON at cmake configure."
                "\nYou could also specify a BLAS vendor to look for by setting -DBLA_VENDOR=blas_vendor_name."
                "\nList of possible BLAS vendor: Goto, ATLAS PhiPACK, CXML, DXML, SunPerf, SCSL, SGIMATH, IBMESSL, Intel10_32 (intel mkl v10 32 bit),"
                "Intel10_64lp (intel mkl v10 64 bit, lp thread model, lp64 model), Intel10_64lp_seq (intel mkl v10 64 bit, sequential code, lp64 model),"
                "Intel( older versions of mkl 32 and 64 bit), ACML, ACML_MP, ACML_GPU, Apple, NAS, Generic")
            if(BLAS_FIND_REQUIRED)
                message(FATAL_ERROR
                "A required library with BLAS95 API not found. Please specify library location.")
            else()
                message(STATUS
                "A library with BLAS95 API not found. Please specify library location.")
            endif()
        endif(BLAS95_FOUND)
    endif(NOT BLAS_FIND_QUIETLY)

    set(BLAS_FOUND TRUE)
    set(BLAS_LIBRARIES "${BLAS95_LIBRARIES}")
    
else(BLA_F95)

    if(BLAS_LIBRARIES)
        set(BLAS_FOUND TRUE)
    else()
        set(BLAS_FOUND FALSE)
    endif()

    if(NOT BLAS_FIND_QUIETLY)
        if(BLAS_FOUND)
            message(STATUS "A library with BLAS API found.")
            message(STATUS "BLAS_LIBRARIES ${BLAS_LIBRARIES}")
        else(BLAS_FOUND)
            message(WARNING "BLA_VENDOR has been set to ${BLA_VENDOR} but blas libraries could not be found or check of symbols failed."
                "\nPlease indicate where to find blas libraries. You have three options:\n"
                "- Option 1: Provide the root directory of BLAS library with cmake option: -DBLAS_DIR=your/path/to/blas\n"
                "- Option 2: Provide the directory where to find BLAS libraries with cmake option: -DBLAS_LIBDIR=your/path/to/blas/libs\n"
                "- Option 3: Update your environment variable (Linux: LD_LIBRARY_PATH, Windows: LIB, Mac: DYLD_LIBRARY_PATH)\n"                
                "\nTo follow libraries detection more precisely you can activate a verbose mode with -DBLAS_VERBOSE=ON at cmake configure."
                "\nYou could also specify a BLAS vendor to look for by setting -DBLA_VENDOR=blas_vendor_name."
                "\nList of possible BLAS vendor: Goto, ATLAS PhiPACK, CXML, DXML, SunPerf, SCSL, SGIMATH, IBMESSL, Intel10_32 (intel mkl v10 32 bit),"
                "Intel10_64lp (intel mkl v10 64 bit, lp thread model, lp64 model), Intel10_64lp_seq (intel mkl v10 64 bit, sequential code, lp64 model),"
                "Intel( older versions of mkl 32 and 64 bit), ACML, ACML_MP, ACML_GPU, Apple, NAS, Generic")
            if(BLAS_FIND_REQUIRED)
                message(FATAL_ERROR
                    "A required library with BLAS API not found. Please specify library location.")
            else()
                message(STATUS
                    "A library with BLAS API not found. Please specify library location.")
            endif()                      
        endif(BLAS_FOUND)
    endif(NOT BLAS_FIND_QUIETLY)

endif(BLA_F95)

set(CMAKE_FIND_LIBRARY_SUFFIXES ${_blas_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES})