IncrementalEngine.ml 17 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13
(******************************************************************************)
(*                                                                            *)
(*                                   Menhir                                   *)
(*                                                                            *)
(*                       François Pottier, Inria Paris                        *)
(*              Yann Régis-Gianas, PPS, Université Paris Diderot              *)
(*                                                                            *)
(*  Copyright Inria. All rights reserved. This file is distributed under the  *)
(*  terms of the GNU Library General Public License version 2, with a         *)
(*  special exception on linking, as described in the file LICENSE.           *)
(*                                                                            *)
(******************************************************************************)

14 15
type position = Lexing.position

16 17
open General

18 19 20 21 22 23 24 25 26
(* This signature describes the incremental LR engine. *)

(* In this mode, the user controls the lexer, and the parser suspends
   itself when it needs to read a new token. *)

module type INCREMENTAL_ENGINE = sig

  type token

27 28
  (* The type ['a checkpoint] represents an intermediate or final state of the
     parser. An intermediate checkpoint is a suspension: it records the parser's
29 30 31 32
     current state, and allows parsing to be resumed. The parameter ['a] is
     the type of the semantic value that will eventually be produced if the
     parser succeeds. *)

33
  (* [Accepted] and [Rejected] are final checkpoints. [Accepted] carries a
34 35
     semantic value. *)

36
  (* [InputNeeded] is an intermediate checkpoint. It means that the parser wishes
37 38
     to read one token before continuing. *)

39
  (* [Shifting] is an intermediate checkpoint. It means that the parser is taking
40 41 42 43 44
     a shift transition. It exposes the state of the parser before and after
     the transition. The Boolean parameter tells whether the parser intends to
     request a new token after this transition. (It always does, except when
     it is about to accept.) *)

45
  (* [AboutToReduce] is an intermediate checkpoint. It means that the parser is
46 47
     about to perform a reduction step. It exposes the parser's current
     state as well as the production that is about to be reduced. *)
48

49
  (* [HandlingError] is an intermediate checkpoint. It means that the parser has
50
     detected an error and is currently handling it, in several steps. *)
51

52 53 54 55 56 57 58 59 60 61 62 63 64
  (* A value of type ['a env] represents a configuration of the automaton:
     current state, stack, lookahead token, etc. The parameter ['a] is the
     type of the semantic value that will eventually be produced if the parser
     succeeds. *)

  (* In normal operation, the parser works with checkpoints: see the functions
     [offer] and [resume]. However, it is also possible to work directly with
     environments (see the functions [pop], [force_reduction], and [feed]) and
     to reconstruct a checkpoint out of an environment (see [input_needed]).
     This is considered advanced functionality; its purpose is to allow error
     recovery strategies to be programmed by the user. *)

  type 'a env
65

66 67
  type production

68
  type 'a checkpoint = private
69 70 71 72
    | InputNeeded of 'a env
    | Shifting of 'a env * 'a env * bool
    | AboutToReduce of 'a env * production
    | HandlingError of 'a env
73 74 75 76
    | Accepted of 'a
    | Rejected

  (* [offer] allows the user to resume the parser after it has suspended
77 78
     itself with a checkpoint of the form [InputNeeded env]. [offer] expects the
     old checkpoint as well as a new token and produces a new checkpoint. It does not
79
     raise any exception. *)
80 81

  val offer:
82
    'a checkpoint ->
83
    token * position * position ->
84
    'a checkpoint
85

86
  (* [resume] allows the user to resume the parser after it has suspended
87 88 89
     itself with a checkpoint of the form [AboutToReduce (env, prod)] or
     [HandlingError env]. [resume] expects the old checkpoint and produces a new
     checkpoint. It does not raise any exception. *)
90

91
  val resume:
92 93
    'a checkpoint ->
    'a checkpoint
94

95 96 97 98
  (* A token supplier is a function of no arguments which delivers a new token
     (together with its start and end positions) every time it is called. *)

  type supplier =
99
    unit -> token * position * position
100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115

  (* A pair of a lexer and a lexing buffer can be easily turned into a supplier. *)

  val lexer_lexbuf_to_supplier:
    (Lexing.lexbuf -> token) ->
    Lexing.lexbuf ->
    supplier

  (* The functions [offer] and [resume] are sufficient to write a parser loop.
     One can imagine many variations (which is why we expose these functions
     in the first place!). Here, we expose a few variations of the main loop,
     ready for use. *)

  (* [loop supplier checkpoint] begins parsing from [checkpoint], reading
     tokens from [supplier]. It continues parsing until it reaches a
     checkpoint of the form [Accepted v] or [Rejected]. In the former case, it
116
     returns [v]. In the latter case, it raises the exception [Error]. *)
117 118 119 120 121 122 123

  val loop: supplier -> 'a checkpoint -> 'a

  (* [loop_handle succeed fail supplier checkpoint] begins parsing from
     [checkpoint], reading tokens from [supplier]. It continues parsing until
     it reaches a checkpoint of the form [Accepted v] or [HandlingError env]
     (or [Rejected], but that should not happen, as [HandlingError _] will be
124 125
     observed first). In the former case, it calls [succeed v]. In the latter
     case, it calls [fail] with this checkpoint. It cannot raise [Error].
126 127 128 129

     This means that Menhir's traditional error-handling procedure (which pops
     the stack until a state that can act on the [error] token is found) does
     not get a chance to run. Instead, the user can implement her own error
130
     handling code, in the [fail] continuation. *)
131 132 133 134 135

  val loop_handle:
    ('a -> 'answer) ->
    ('a checkpoint -> 'answer) ->
    supplier -> 'a checkpoint -> 'answer
136

137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154
  (* [loop_handle_undo] is analogous to [loop_handle], except it passes a pair
     of checkpoints to the failure continuation.

     The first (and oldest) checkpoint is the last [InputNeeded] checkpoint that
     was encountered before the error was detected. The second (and newest)
     checkpoint is where the error was detected, as in [loop_handle]. Going back
     to the first checkpoint can be thought of as undoing any reductions that
     were performed after seeing the problematic token. (These reductions must
     be default reductions or spurious reductions.)

     [loop_handle_undo] must initially be applied to an [InputNeeded] checkpoint.
     The parser's initial checkpoints satisfy this constraint. *)

  val loop_handle_undo:
    ('a -> 'answer) ->
    ('a checkpoint -> 'a checkpoint -> 'answer) ->
    supplier -> 'a checkpoint -> 'answer

POTTIER Francois's avatar
POTTIER Francois committed
155 156 157 158 159 160 161 162 163 164 165 166
  (* [loop_test f checkpoint accu] assumes that [checkpoint] has been obtained
     by submitting a token to the parser. It runs the parser from [checkpoint],
     through an arbitrary number of reductions, until the parser either accepts
     this token (i.e., shifts) or rejects it (i.e., signals an error). If the
     parser decides to shift, then the accumulator is updated by applying the
     user function [f] to the [env] just before shifting and to the old [accu].
     Otherwise, the accumulator is not updated, i.e., [accu] is returned. *)

  (* It is desirable that the semantic actions be side-effect free, or that
     their side-effects be harmless (replayable). *)

  val loop_test:
167
    ('a env -> 'accu -> 'accu) ->
POTTIER Francois's avatar
POTTIER Francois committed
168 169
    'a checkpoint -> 'accu -> 'accu

POTTIER Francois's avatar
POTTIER Francois committed
170 171 172 173 174 175 176 177 178 179 180 181 182 183 184
  (* The function [loop_test] can be used, after an error has been detected, to
     dynamically test which tokens would have been accepted at this point. We
     provide this test, ready for use. *)

  (* For completeness, one must undo any spurious reductions before carrying out
     this test -- that is, one must apply [acceptable] to the FIRST checkpoint
     that is passed by [loop_handle_undo] to its failure continuation. *)

  (* This test causes some semantic actions to be run! The semantic actions
     should be side-effect free, or their side-effects should be harmless. *)

  (* The position [pos] is used as the start and end positions of the
     hypothetical token, and may be picked up by the semantic actions. We
     suggest using the position where the error was detected. *)

185
  val acceptable: 'a checkpoint -> token -> position -> bool
POTTIER Francois's avatar
POTTIER Francois committed
186

187 188 189 190 191
  (* [pop env] returns a new environment, where the parser's top stack cell
     has been popped off. (If the stack is empty, [None] is returned.) This
     amounts to pretending that the (terminal or nonterminal) symbol that
     corresponds to this stack cell has not been read. *)

192
  val pop: 'a env -> 'a env option
193 194 195 196 197 198 199 200

  (* [force_reduction prod env] should be called only if in the current state
     (as determined by [env]) the parser is capable of reducing the production
     [prod]. If this condition is satisfied, then this production is reduced,
     which means that its semantic action is executed (this can have side
     effects!) and the automaton makes a goto (nonterminal) transition. If
     this condition is not satisfied, [Invalid_argument _] is raised. *)

201
  val force_reduction: production -> 'a env -> 'a env
202 203 204 205 206 207 208 209 210 211 212 213 214 215 216

  (* [input_needed env] returns [InputNeeded env]. That is, out of an [env]
     that might have been obtained via a series of calls to the functions
     [pop], [force_reduction], [feed], etc., it produces a checkpoint, which
     can be used to resume normal parsing, by supplying this checkpoint as an
     argument to [offer]. *)

  (* This function should be used with some care. It could "mess up the
     lookahead" in the sense that it allows parsing to resume in an arbitrary
     state [s] with an arbitrary lookahead symbol [t], even though Menhir's
     reachability analysis (menhir --list-errors) might well think that it is
     impossible to reach this particular configuration. If one is using
     Menhir's new error reporting facility, this could cause the parser to
     reach an error state for which no error message has been prepared. *)

217
  val input_needed: 'a env -> 'a checkpoint
218

219 220 221 222 223 224
  (* The abstract type ['a lr1state] describes the non-initial states of the
     LR(1) automaton. The index ['a] represents the type of the semantic value
     associated with this state's incoming symbol. *)

  type 'a lr1state

225 226 227 228
  (* The states of the LR(1) automaton are numbered (from 0 and up). *)

  val number: _ lr1state -> int

229 230 231 232 233
  (* [find_default_reduction s] returns [Some prod] if the state [s] has a
     default reduction of production [prod], and returns [None] otherwise. *)

  val find_default_reduction: _ lr1state -> production option

234 235 236
  (* An element is a pair of a non-initial state [s] and a semantic value [v]
     associated with the incoming symbol of this state. The idea is, the value
     [v] was pushed onto the stack just before the state [s] was entered. Thus,
237
     for some type ['a], the state [s] has type ['a lr1state] and the value [v]
238 239 240
     has type ['a]. In other words, the type [element] is an existential type. *)

  type element =
241
    | Element: 'a lr1state * 'a * position * position -> element
242 243

  (* The parser's stack is (or, more precisely, can be viewed as) a stream of
POTTIER Francois's avatar
POTTIER Francois committed
244
     elements. The type [stream] is defined by the module [General]. *)
245 246 247 248

  type stack =
    element stream

249 250 251 252
  (* This is the parser's stack, a stream of elements. This stream is empty if
     the parser is in an initial state; otherwise, it is non-empty.  The LR(1)
     automaton's current state is the one found in the top element of the
     stack. *)
253

254
  val stack: 'a env -> stack
255

256 257 258
  (* These are the start and end positions of the current lookahead token. If
     invoked in an initial state, this function returns a pair of twice the
     initial position. *)
259

260
  val positions: 'a env -> position * position
261

262 263 264 265 266
  (* This tells whether the parser is about to perform a default reduction.
     In particular, when applied to an environment taken from a result of
     the form [AboutToReduce (env, prod)], this tells whether the reduction
     that is about to take place is a default reduction. *)

267
  val has_default_reduction: 'a env -> bool
268

269
end
270

271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295
(* This signature is a fragment of the inspection API that is made available
   to the user when [--inspection] is used. This fragment contains type
   definitions for symbols. *)

module type SYMBOLS = sig

  (* The type ['a terminal] represents a terminal symbol. The type ['a
     nonterminal] represents a nonterminal symbol. In both cases, the index
     ['a] represents the type of the semantic values associated with this
     symbol. The concrete definitions of these types are generated. *)

  type 'a terminal
  type 'a nonterminal

  (* The type ['a symbol] represents a terminal or nonterminal symbol. It is
     the disjoint union of the types ['a terminal] and ['a nonterminal]. *)

  type 'a symbol =
    | T : 'a terminal -> 'a symbol
    | N : 'a nonterminal -> 'a symbol

  (* The type [xsymbol] is an existentially quantified version of the type
     ['a symbol]. This type is useful in situations where the index ['a]
     is not statically known. *)

296
  type xsymbol =
297 298 299 300
    | X : 'a symbol -> xsymbol

end

301 302
(* This signature describes the inspection API that is made available to the
   user when [--inspection] is used. *)
303 304 305

module type INSPECTION = sig

306 307 308 309
  (* The types of symbols are described above. *)

  include SYMBOLS

310 311
  (* The type ['a lr1state] is meant to be the same as in [INCREMENTAL_ENGINE]. *)

312
  type 'a lr1state
313

314 315 316 317
  (* The type [production] is meant to be the same as in [INCREMENTAL_ENGINE].
     It represents a production of the grammar. A production can be examined
     via the functions [lhs] and [rhs] below. *)

318 319
  type production

320 321 322 323
  (* An LR(0) item is a pair of a production [prod] and a valid index [i] into
     this production. That is, if the length of [rhs prod] is [n], then [i] is
     comprised between 0 and [n], inclusive. *)

324
  type item =
325 326
      production * int

327 328 329 330 331 332 333 334
  (* Ordering functions. *)

  val compare_terminals: _ terminal -> _ terminal -> int
  val compare_nonterminals: _ nonterminal -> _ nonterminal -> int
  val compare_symbols: xsymbol -> xsymbol -> int
  val compare_productions: production -> production -> int
  val compare_items: item -> item -> int

335 336 337 338 339 340
  (* [incoming_symbol s] is the incoming symbol of the state [s], that is,
     the symbol that the parser must recognize before (has recognized when)
     it enters the state [s]. This function gives access to the semantic
     value [v] stored in a stack element [Element (s, v, _, _)]. Indeed,
     by case analysis on the symbol [incoming_symbol s], one discovers the
     type ['a] of the value [v]. *)
341

POTTIER Francois's avatar
POTTIER Francois committed
342
  val incoming_symbol: 'a lr1state -> 'a symbol
343

344 345 346 347 348 349
  (* [items s] is the set of the LR(0) items in the LR(0) core of the LR(1)
     state [s]. This set is not epsilon-closed. This set is presented as a
     list, in an arbitrary order. *)

  val items: _ lr1state -> item list

350 351 352
  (* [lhs prod] is the left-hand side of the production [prod]. This is
     always a non-terminal symbol. *)

353 354
  val lhs: production -> xsymbol

355 356 357
  (* [rhs prod] is the right-hand side of the production [prod]. This is
     a (possibly empty) sequence of (terminal or nonterminal) symbols. *)

358 359
  val rhs: production -> xsymbol list

360 361 362 363
  (* [nullable nt] tells whether the non-terminal symbol [nt] is nullable.
     That is, it is true if and only if this symbol produces the empty
     word [epsilon]. *)

364
  val nullable: _ nonterminal -> bool
365

366 367 368 369
  (* [first nt t] tells whether the FIRST set of the nonterminal symbol [nt]
     contains the terminal symbol [t]. That is, it is true if and only if
     [nt] produces a word that begins with [t]. *)

370 371 372 373 374 375
  val first: _ nonterminal -> _ terminal -> bool

  (* [xfirst] is analogous to [first], but expects a first argument of type
     [xsymbol] instead of [_ terminal]. *)

  val xfirst: xsymbol -> _ terminal -> bool
376

377 378 379 380 381 382 383
  (* [foreach_terminal] enumerates the terminal symbols, including [error].
     [foreach_terminal_but_error] enumerates the terminal symbols, excluding
     [error]. *)

  val foreach_terminal:           (xsymbol -> 'a -> 'a) -> 'a -> 'a
  val foreach_terminal_but_error: (xsymbol -> 'a -> 'a) -> 'a -> 'a

384 385
  (* The type [env] is meant to be the same as in [INCREMENTAL_ENGINE]. *)

386
  type 'a env
387 388 389 390 391 392 393 394 395

  (* [feed symbol startp semv endp env] forces the parser to consume the
     (terminal or nonterminal) symbol [symbol], accompanied with the semantic
     value [semv] and with the positions [startp] and [endp]. Thus, the
     automaton makes a transition, and reaches a new state. The stack grows by
     one cell. This operation is permitted only if the current state (as
     determined by [env]) has an outgoing transition labeled with [symbol].
     Otherwise, [Invalid_argument _] is raised. *)

396
  val feed: 'a symbol -> position -> 'a -> position -> 'b env -> 'b env
397

398 399
end

400 401 402 403 404 405 406 407 408
(* This signature combines the incremental API and the inspection API. *)

module type EVERYTHING = sig

  include INCREMENTAL_ENGINE

  include INSPECTION
    with type 'a lr1state := 'a lr1state
    with type production := production
409
    with type 'a env := 'a env
410 411

end