LRijkstra.ml 45.9 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14
(* The purpose of this algorithm is to find, for each pair of a state [s]
   and a terminal symbol [z] such that looking at [z] in state [s] causes
   an error, a minimal path (starting in some initial state) that actually
   triggers this error. *)

(* This is potentially useful for grammar designers who wish to better
   understand the properties of their grammar, or who wish to produce a
   list of all possible syntax errors (or, at least, one syntax error in
   each automaton state where an error may occur). *)

(* The problem seems rather tricky. One might think that it suffices to
   compute shortest paths in the automaton, and to use [Analysis.minimal] to
   replace each non-terminal symbol in a path with a minimal word that this
   symbol generates. One can indeed do so, but this yields only a lower bound
POTTIER Francois's avatar
POTTIER Francois committed
15 16 17 18 19 20
   on the actual shortest path to the error at [s, z]. Indeed, several
   difficulties arise, including the fact that reductions are subject to a
   lookahead hypothesis; the fact that some states have a default reduction,
   hence will never trigger an error; the fact that conflict resolution
   removes some (shift or reduce) actions, hence may suppress the shortest
   path. *)
21

22 23 24 25 26 27 28 29 30 31 32
(* We explicitly choose to ignore the [error] token. Thus, we disregard any
   reductions or transitions that take place when the lookahead symbol is
   [error]. As a result, any state whose incoming symbol is [error] is found
   unreachable. It would be too complicated to have to create a first error in
   order to be able to take certain transitions or drop certain parts of the
   input. *)

(* We never work with the terminal symbol [#] either. This symbol never
   appears in the maps returned by [Lr1.transitions] and [Lr1.reductions].
   Thus, in principle, we work with ``real'' terminal symbols only. However,
   we encode [any] as [#] -- see below. *)
33

34
(* NOTE: THIS FILE IS COMPILED WITH -noassert BY DEFAULT. If you would like
35 36
   the assertions to be tested at runtime, change that in the file _tags.
   The performance impact of the assertions is about 10%. *)
37

38 39 40
(* ------------------------------------------------------------------------ *)

(* To delay the side effects performed by this module, we wrap everything in
41
   in a big functor. The functor also serves to pass verbosity parameters. *)
42

43 44 45 46 47 48 49
module Run (X : sig
  (* If [verbose] is set, produce various messages on [stderr]. *)
  val verbose: bool
  (* If [statistics] is defined, it is interpreted as the name of
     a file to which one line of statistics is appended. *)
  val statistics: string option
end) = struct
50

51
open Grammar
52

53 54 55 56 57 58 59 60 61 62 63
(* ------------------------------------------------------------------------ *)

(* Record our start time. *)

let now () =
  match X.statistics with
  | Some _ ->
      Unix.((times()).tms_utime)
  | None ->
      0.0

64
let start =
65
  now()
66

67 68
(* ------------------------------------------------------------------------ *)

69 70
(* Because of our encoding of terminal symbols as 8-bit characters, this
   algorithm supports at most 256 terminal symbols. *)
71 72

let () =
73
  if Terminal.n > 256 then
74
    Error.error [] (Printf.sprintf
75
      "--list-errors supports at most 256 terminal symbols.\n\
76 77 78 79 80
       The grammar has %d terminal symbols." Terminal.n
    )

(* ------------------------------------------------------------------------ *)

81 82 83 84 85
(* Build a module that represents words as (hash-consed) strings. Note:
   this functor application has a side effect (it allocates memory, and
   more importantly, it may fail). *)

module W = Terminal.Word(struct end)
86

87 88
(* ------------------------------------------------------------------------ *)

89 90
(* The [error] token may appear in the maps returned by [Lr1.transitions]
   and [Lr1.reductions], so we sometimes need to explicitly check for it. *)
91

92
let non_error z =
93
  not (Terminal.equal z Terminal.error)
94

95 96 97 98
(* We introduce a pseudo-terminal symbol [any]. It is used in several places
   later on, in particular in the field [fact.lookahead], to encode the
   absence of a lookahead hypothesis -- i.e., any terminal symbol will do. *)

99 100 101 102 103
(* We choose to encode [any] as [#]. There is no risk of confusion, since we
   do not use [#] anywhere. Thus, the assertion [Terminal.real z] implies
   [z <> any]. *)

let any =
104
  Terminal.sharp
105

106 107
(* ------------------------------------------------------------------------ *)

108 109 110 111 112
(* We begin with a number of auxiliary functions that provide information
   about the LR(1) automaton. These functions could perhaps be moved to a
   separate module. We keep them here, for the moment, because they are not
   used anywhere else. *)

POTTIER Francois's avatar
POTTIER Francois committed
113 114 115
(* [reductions_on s z] is the list of reductions permitted in state [s] when
   the lookahead symbol is [z]. This is a list of zero or one elements. This
   does not take default reductions into account. *)
116

POTTIER Francois's avatar
POTTIER Francois committed
117
let reductions_on s z : Production.index list =
118
  assert (Terminal.real z);
119 120 121 122 123
  try
    TerminalMap.find z (Lr1.reductions s)
  with Not_found ->
    []

124 125 126
(* [has_reduction s z] tells whether state [s] is willing to reduce some
   production (and if so, which one) when the lookahead symbol is [z]. It
   takes a possible default reduction into account. *)
127 128

let has_reduction s z : Production.index option =
129
  assert (Terminal.real z);
130 131 132 133
  match Invariant.has_default_reduction s with
  | Some (prod, _) ->
      Some prod
  | None ->
POTTIER Francois's avatar
POTTIER Francois committed
134
      match reductions_on s z with
135 136 137 138 139 140
      | prod :: prods ->
          assert (prods = []);
          Some prod
      | [] ->
          None

141 142 143 144 145 146 147 148 149
(* [can_reduce s prod] indicates whether state [s] is able to reduce
   production [prod] (either as a default reduction, or as a normal
   reduction). *)

let can_reduce s prod =
  match Invariant.has_default_reduction s with
  | Some (prod', _) when prod = prod' ->
      true
  | _ ->
150
      TerminalMap.fold (fun z prods accu ->
151 152
        (* A reduction on [#] is always a default reduction. (See [lr1.ml].) *)
        assert (not (Terminal.equal z Terminal.sharp));
153
        accu || non_error z && List.mem prod prods
154 155
      ) (Lr1.reductions s) false

156 157
(* [causes_an_error s z] tells whether state [s] will initiate an error on the
   lookahead symbol [z]. *)
158

159
let causes_an_error s z : bool =
160
  assert (Terminal.real z);
161 162 163 164
  match Invariant.has_default_reduction s with
  | Some _ ->
      false
  | None ->
POTTIER Francois's avatar
POTTIER Francois committed
165
      reductions_on s z = [] &&
166 167
      not (SymbolMap.mem (Symbol.T z) (Lr1.transitions s))

168
(* [foreach_terminal f] applies the function [f] to every terminal symbol in
169
   turn, except [error] and [#]. *)
170

171 172
let foreach_terminal =
  Terminal.iter_real
173

174 175 176
(* [foreach_terminal_not_causing_an_error s f] applies the function [f] to
   every terminal symbol [z] such that [causes_an_error s z] is false. This
   could be implemented in a naive manner using [foreach_terminal] and
POTTIER Francois's avatar
POTTIER Francois committed
177
   [causes_an_error]. This implementation is significantly more efficient. *)
178

179 180 181
let foreach_terminal_not_causing_an_error s f =
  match Invariant.has_default_reduction s with
  | Some _ ->
182
      (* There is a default reduction. No symbol causes an error. *)
183 184
      foreach_terminal f
  | None ->
185 186 187
      (* Enumerate every terminal symbol [z] for which there is a
         reduction. *)
      TerminalMap.iter (fun z _ ->
188 189 190
        (* A reduction on [#] is always a default reduction. (See [lr1.ml].) *)
        assert (not (Terminal.equal z Terminal.sharp));
        if non_error z then
191
          f z
192
      ) (Lr1.reductions s);
193 194
      (* Enumerate every terminal symbol [z] for which there is a
         transition. *)
195 196
      SymbolMap.iter (fun sym _ ->
        match sym with
197
        | Symbol.T z ->
198 199
            assert (not (Terminal.equal z Terminal.sharp));
            if non_error z then
200
              f z
201 202 203 204
        | Symbol.N _ ->
            ()
      ) (Lr1.transitions s)

205
(* Let us say a state [s] is solid if its incoming symbol is a terminal symbol
POTTIER Francois's avatar
POTTIER Francois committed
206 207
   (or if it has no incoming symbol at all, i.e., it is an initial state). It
   is fragile if its incoming symbol is a non-terminal symbol. *)
208 209 210 211 212

let is_solid s =
  match Lr1.incoming_symbol s with
  | None
  | Some (Symbol.T _) ->
POTTIER Francois's avatar
POTTIER Francois committed
213
    true
214
  | Some (Symbol.N _) ->
POTTIER Francois's avatar
POTTIER Francois committed
215
    false
216

217 218
(* ------------------------------------------------------------------------ *)

POTTIER Francois's avatar
POTTIER Francois committed
219 220 221 222 223 224 225 226 227
(* Suppose [s] is a state that carries an outgoing edge labeled with a
   non-terminal symbol [nt]. We are interested in finding out how this edge
   can be taken. In order to do that, we must determine how, by starting in
   [s], one can follow a path that corresponds to (the right-hand side of) a
   production [prod] associated with [nt]. There are in general several such
   productions. The paths that they determine in the automaton form a "star".
   We represent the star rooted at [s] as a trie. For every state [s], the
   star rooted at [s] is constructed in advance, before the algorithm runs.
   While the algorithm runs, a point in the trie (that is, a sub-trie) tells
POTTIER Francois's avatar
Typo.  
POTTIER Francois committed
228
   us where we come from, where we are, and which production(s) we are hoping
POTTIER Francois's avatar
POTTIER Francois committed
229 230
   to reduce in the future. *)

231 232 233
let grammar_uses_error =
  ref false

234 235 236
module Trie : sig

  type trie
237 238 239 240

  (* [star s] creates a (new) trie whose source is [s], populated with its
     branches. (There is one branch for every production [prod] associated
     with every non-terminal symbol [nt] for which [s] carries an outgoing
241
     edge.) If the star turns out to be trivial then [None] is returned. *)
242 243
  val star: Lr1.node -> trie option

244 245 246 247
  (* After [star s] has been called, [size (Lr1.number s)] reports the size
     of the trie that has been constructed for state [s]. *)
  val size: int -> int

248 249 250 251
  (* After [star] has been called a number of times, [cumulated_size()]
     reports the total size of the tries that have been constructed. *)
  val cumulated_size: unit -> int

252 253 254 255 256 257 258 259
  (* Every (sub-)trie has a unique identity. (One can think of it as its
     address.) [compare] compares the identity of two tries. This can be
     used, e.g., to set up a map whose keys are tries. *)
  val compare: trie -> trie -> int

  (* [source t] returns the source state of the (sub-)trie [t]. This is
     the root of the star of which [t] is a sub-trie. In other words, this
     tells us "where we come from". *)
260
  val source: trie -> Lr1.node
POTTIER Francois's avatar
POTTIER Francois committed
261 262

  (* [current t] returns the current state of the (sub-)trie [t]. This is
263 264
     the root of the sub-trie [t]. In other words, this tells us "where
     we are". *)
POTTIER Francois's avatar
POTTIER Francois committed
265
  val current: trie -> Lr1.node
266

267 268 269 270 271
  (* [accepts prod t] tells whether the current state of the trie [t] is
     the end of a branch associated with production [prod]. If so, this
     means that we have successfully followed a path that corresponds to
     the right-hand side of production [prod]. *)
  val accepts: Production.index -> trie -> bool
272

273 274 275 276 277 278 279 280
  (* [step sym t] is the immediate sub-trie of [t] along the symbol [sym].
     This function raises [Not_found] if [t] has no child labeled [sym]. *)
  val step: Symbol.t -> trie -> trie

  (* [verbose()] outputs debugging & performance information. *)
  val verbose: unit -> unit

end = struct
281

282 283
  (* A trie has the following structure. *)

284
  type trie = {
285 286 287
    (* A unique identity, used by [compare]. The trie construction code
       ensures that these numbers are indeed unique: see [fresh], [insert],
       [star]. *)
288
    identity: int;
289
    (* The root state of this star: "where we come from". *)
290
    source: Lr1.node;
291
    (* The current state, i.e., the root of this sub-trie: "where we are". *)
POTTIER Francois's avatar
POTTIER Francois committed
292
    current: Lr1.node;
293 294 295
    (* The productions that we can reduce in the current state. In other
       words, if this list is nonempty, then the current state is the end
       of one (or several) branches. It can nonetheless have children. *)
296
    productions: Production.index list;
297 298
    (* The children, or sub-tries. *)
    transitions: trie SymbolMap.t
299
  }
300

301
  (* This counter is used by [mktrie] to produce unique identities. *)
302 303
  let c = ref 0

304
  (* This smart constructor creates a new trie with a unique identity. *)
POTTIER Francois's avatar
POTTIER Francois committed
305
  let mktrie source current productions transitions =
306
    let identity = Misc.postincrement c in
POTTIER Francois's avatar
POTTIER Francois committed
307
    { identity; source; current; productions; transitions }
308

309 310
  exception DeadBranch

311
  let rec insert w prod t =
312 313
    match w with
    | [] ->
POTTIER Francois's avatar
POTTIER Francois committed
314
        (* We check whether the current state [t.current] is able to reduce
315 316 317 318 319
           production [prod]. (If [prod] cannot be reduced, the reduction
           action must have been suppressed by conflict resolution.) If not,
           then this branch is dead. This test is superfluous (i.e., it would
           be OK to conservatively assume that [prod] can be reduced) but
           allows us to build a slightly smaller star in some cases. *)
POTTIER Francois's avatar
POTTIER Francois committed
320
        if can_reduce t.current prod then
321 322 323 324 325 326
          (* We consume (update) the trie [t], so there is no need to allocate
             a new stamp. (Of course we could allocate a new stamp, but I prefer
             to be precise.) *)
          { t with productions = prod :: t.productions }
        else
          raise DeadBranch
327
    | (Symbol.T t) :: _ when Terminal.equal t Terminal.error ->
328
         grammar_uses_error := true;
329
         raise DeadBranch
330
    | a :: w ->
POTTIER Francois's avatar
POTTIER Francois committed
331
        (* Check if there is a transition labeled [a] out of [t.current]. If
332 333
           there is, we add a child to the trie [t]. If there isn't, then it
           must have been removed by conflict resolution. (Indeed, it must be
334 335 336
           present in a canonical automaton.) We could in this case return an
           unchanged sub-trie. We can do slightly better: we abort the whole
           insertion, so as to return an unchanged toplevel trie. *)
POTTIER Francois's avatar
POTTIER Francois committed
337
        match SymbolMap.find a (Lr1.transitions t.current) with
338
        | successor ->
339 340 341 342 343 344 345 346
            (* Find our child at [a], or create it. *)
            let t' =
              try
                SymbolMap.find a t.transitions
              with Not_found ->
                mktrie t.source successor [] SymbolMap.empty
            in
            (* Update the child [t']. *)
347
            let t' = insert w prod t' in
348 349
            (* Update [t]. Again, no need to allocate a new stamp. *)
            { t with transitions = SymbolMap.add a t' t.transitions }
350
        | exception Not_found ->
351
            raise DeadBranch
352

353 354 355 356 357
  (* [insert prod t] inserts a new branch, corresponding to production
     [prod], into the trie [t]. This function consumes its argument,
     which should no longer be used afterwards. *)
  let insert prod t =
    let w = Array.to_list (Production.rhs prod) in
358 359 360 361 362 363
    let save = !c in
    try
      insert w prod t
    with DeadBranch ->
      c := save;
      t
364

365 366 367 368
  (* [fresh s] creates a new empty trie whose source is [s]. *)
  let fresh source =
    mktrie source source [] SymbolMap.empty

369 370 371
  (* The star at [s] is obtained by starting with a fresh empty trie and
     inserting into it every production [prod] whose left-hand side [nt]
     is the label of an outgoing edge at [s]. *)
372 373 374 375 376 377 378 379 380
  let star s =
    SymbolMap.fold (fun sym _ accu ->
      match sym with
      | Symbol.T _ ->
          accu
      | Symbol.N nt ->
          Production.foldnt nt accu insert
    ) (Lr1.transitions s) (fresh s)

381 382 383 384 385 386 387
  (* A trie [t] is nontrivial if it has at least one branch, i.e., contains at
     least one sub-trie whose [productions] field is nonempty. Trivia: a trie
     of size greater than 1 is necessarily nontrivial, but the converse is not
     true: a nontrivial trie can have size 1. (This occurs if all productions
     have zero length.) *)
  let trivial t =
    t.productions = [] && SymbolMap.is_empty t.transitions
388

389 390
  (* Redefine [star] to include a [nontrivial] test and to record the size of
     the newly built trie. *)
391 392 393 394

  let size =
    Array.make Lr1.n (-1)

395
  let star s =
396
    let initial = !c in
397
    let t = star s in
398 399
    let final = !c in
    size.(Lr1.number s) <- final - initial;
400
    if trivial t then None else Some t
401

402 403 404 405
  let size s =
    assert (size.(s) >= 0);
    size.(s)

406 407 408
  let cumulated_size () =
    !c

POTTIER Francois's avatar
POTTIER Francois committed
409
  let compare t1 t2 =
410
    Pervasives.compare t1.identity t2.identity
411

412 413 414
  let source t =
    t.source

POTTIER Francois's avatar
POTTIER Francois committed
415 416
  let current t =
    t.current
417

418 419 420
  let accepts prod t =
    List.mem prod t.productions

421
  let step a t =
422
    SymbolMap.find a t.transitions (* careful: may raise [Not_found] *)
423

424
  let verbose () =
425
    Printf.eprintf "Cumulated star size: %d\n%!" (cumulated_size())
426

427 428
end

POTTIER Francois's avatar
POTTIER Francois committed
429 430
(* ------------------------------------------------------------------------ *)

POTTIER Francois's avatar
POTTIER Francois committed
431 432 433 434 435 436
(* The main algorithm, [LRijkstra], accumulates facts. A fact is a triple of a
   position (that is, a sub-trie), a word, and a lookahead assumption. Such a
   fact means that this position can be reached, from the source state
   [Trie.source fact.position], by consuming [fact.word], under the assumption
   that the next input symbol is [fact.lookahead]. *)

437 438
(* We allow [fact.lookahead] to be [any] so as to indicate that this fact does
   not have a lookahead assumption. *)
POTTIER Francois's avatar
POTTIER Francois committed
439

440
type fact = {
441
  position: Trie.trie;
442
  word: W.word;
443
  lookahead: Terminal.t (* may be [any] *)
444 445
}

446 447
(* Accessors. *)

448
let source fact =
449
  Trie.source fact.position
450

POTTIER Francois's avatar
POTTIER Francois committed
451
let current fact =
452
  Trie.current fact.position
453

454 455
(* Two invariants reduce the number of facts that we consider:

456 457 458
   1. If [fact.lookahead] is a real terminal symbol [z] (i.e., not [any]),
      then [z] does not cause an error in the current state [current fact].
      It would be useless to consider a fact that violates this property;
POTTIER Francois's avatar
POTTIER Francois committed
459 460 461
      this cannot possibly lead to a successful reduction. In practice,
      this refinement allows reducing the number of facts that go through
      the queue by a factor of two.
462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479

   2. [fact.lookahead] is [any] iff the current state [current fact] is
      solid. This sounds rather reasonable (when a state is entered
      by shifting, it is entered regardless of which symbol follows)
      and simplifies the implementation of the sub-module [T].

*)

let invariant1 fact =
  fact.lookahead = any || not (causes_an_error (current fact) fact.lookahead)

let invariant2 fact =
  (fact.lookahead = any) = is_solid (current fact)

(* [compatible z a] checks whether the terminal symbol [a] satisfies the
   lookahead assumption [z] -- which can be [any]. *)

let compatible z a =
480 481
  assert (non_error z);
  assert (Terminal.real a);
482 483
  z = any || z = a

POTTIER Francois's avatar
POTTIER Francois committed
484
(* ------------------------------------------------------------------------ *)
485

486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508
(* As in Dijkstra's algorithm, a priority queue contains the facts that await
   examination. The length of [fact.word] serves as the priority of a fact.
   This guarantees that we discover shortest paths. (We never insert into the
   queue a fact whose priority is less than the priority of the last fact
   extracted out of the queue.) *)

(* [LowIntegerPriorityQueue] offers very efficient operations (essentially
   constant time, for a small constant). It exploits the fact that priorities
   are low nonnegative integers. *)

module Q = LowIntegerPriorityQueue

let q =
  Q.create()

(* In principle, there is no need to insert the fact into the queue if [T]
   already stores a comparable fact. We could perform this test in [add].
   However, a quick experiment suggests that this is not worthwhile. The run
   time augments (because membership in [T] is tested twice, upon inserting
   and upon extracting) and the memory consumption does not seem to go down
   significantly. *)

let add fact =
POTTIER Francois's avatar
POTTIER Francois committed
509
  (* [fact.lookahead] can be [any], but cannot be [error] *)
510
  assert (non_error fact.lookahead);
511 512
  assert (invariant1 fact);
  assert (invariant2 fact);
513 514 515
  (* The length of [fact.word] serves as the priority of this fact. *)
  Q.add q fact (W.length fact.word)

POTTIER Francois's avatar
POTTIER Francois committed
516 517
(* ------------------------------------------------------------------------ *)

518 519 520
(* Construct the [star] of every state [s]. Initialize the priority queue. *)

let () =
POTTIER Francois's avatar
POTTIER Francois committed
521
  (* For every state [s]... *)
522
  Lr1.iter (fun s ->
POTTIER Francois's avatar
POTTIER Francois committed
523
    (* If the trie rooted at [s] is nontrivial...*)
524
    match Trie.star s with
POTTIER Francois's avatar
POTTIER Francois committed
525 526 527 528 529 530 531 532 533 534
    | None ->
        ()
    | Some position ->
        (* ...then insert an initial fact into the priority queue. *)
        (* In order to respect invariants 1 and 2, we must distinguish two
           cases. If [s] is solid, then we insert a single fact, whose
           lookahead assumption is [any]. Otherwise, we must insert one
           initial fact for every terminal symbol [z] that does not cause
           an error in state [s]. *)
        let word = W.epsilon in
535
        if is_solid s then
POTTIER Francois's avatar
POTTIER Francois committed
536
          add { position; word; lookahead = any }
537 538
        else
          foreach_terminal_not_causing_an_error s (fun z ->
POTTIER Francois's avatar
POTTIER Francois committed
539
            add { position; word; lookahead = z }
540
          )
POTTIER Francois's avatar
POTTIER Francois committed
541 542 543
  );
  if X.verbose then
    Trie.verbose()
544

545 546 547 548 549 550 551
(* Produce a warning if the grammar uses the [error] pseudo-token. *)

let () =
  if !grammar_uses_error then
    Error.warning []
      "--list-errors ignores all productions that involve the error token."

552 553
(* ------------------------------------------------------------------------ *)

554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571
(* The module [T] maintains a set of known facts. *)

(* Three aspects of a fact are of particular interest:
   - its position [position], given by [fact.position];
   - its first symbol [a], given by [W.first fact.word fact.lookahead];
   - its lookahead assumption [z], given by [fact.lookahead].

   For every triple of [position], [a], and [z], we store at most one fact,
   (whose word has minimal length). Indeed, we are not interested in keeping
   track of several words that produce the same effect. Only the shortest such
   word is of interest.
   
   Thus, the total number of facts accumulated by the algorithm is at most
   [T.n^2], where [T] is the total size of the tries that we have constructed,
   and [n] is the number of terminal symbols. (This number can be quite large.
   [T] can be in the tens of thousands, and [n] can be over one hundred. These
   figures lead to a theoretical upper bound of 100M. In practice, for T=25K
   and n=108, we observe that the algorithm gathers about 7M facts.) *)
572

573
module T : sig
574 575

  (* [register fact] registers the fact [fact]. It returns [true] if this fact
POTTIER Francois's avatar
POTTIER Francois committed
576 577
     is new, i.e., no fact concerning the same triple of [position], [a], and
     [z] was previously known. *)
578 579
  val register: fact -> bool

POTTIER Francois's avatar
POTTIER Francois committed
580
  (* [query current z f] enumerates all known facts whose current state is
581 582
     [current] and whose lookahead assumption is compatible with [z]. The
     symbol [z] must a real terminal symbol, i.e., cannot be [any]. *)
583
  val query: Lr1.node -> Terminal.t -> (fact -> unit) -> unit
584

585 586 587
  (* [size()] returns the number of facts currently stored in the set. *)
  val size: unit -> int

588
  (* [verbose()] outputs debugging & performance information. *)
589
  val verbose: unit -> unit
590

591
end = struct
592

593 594 595 596 597 598 599 600 601 602 603
  (* We need to query the set of facts in two ways. In [register], we must test
     whether a proposed triple of [position], [a], [z] already appears in the
     set. In [query], we must find all facts that match a pair [current, z],
     where [current] is a state. (Note that [position] determines [current], but
     the converse is not true: a position contains more information besides the
     current state.)

     To address these needs, we use a two-level table. The first level is a
     matrix indexed by [current] and [z]. At the second level, we find sets of
     facts, where two facts are considered equal if they have the same triple of
     [position], [a], and [z]. In fact, we know at this level that all facts
604 605 606 607 608 609
     have the same [z] component, so only [position] and [a] are compared.

     Because our facts satisfy invariant 2, [z] is [any] if and only if the
     state [current fact] is solid. This means that we are wasting quite a
     lot of space in the matrix (for a solid state, the whole line is empty,
     except for the [any] column). *)
610

611
  (* The level-2 sets. *)
612 613

  module M =
614
    MySet.Make(struct
615 616
      type t = fact
      let compare fact1 fact2 =
617
        assert (fact1.lookahead = fact2.lookahead);
618
        let c = Trie.compare fact1.position fact2.position in
619
        if c <> 0 then c else
620 621 622
        let z = fact1.lookahead in
        let a1 = W.first fact1.word z
        and a2 = W.first fact2.word z in
623
        (* note: [a1] and [a2] can be [any] here *)
624 625
        Terminal.compare a1 a2
    end)
626

627 628 629
  (* The level-1 matrix. *)

  let table =
630
    Array.make (Lr1.n * Terminal.n) M.empty
631

POTTIER Francois's avatar
POTTIER Francois committed
632
  let index current z =
633
    Terminal.n * (Lr1.number current) + Terminal.t2i z
634

635 636
  let count = ref 0

637
  let register fact =
POTTIER Francois's avatar
POTTIER Francois committed
638
    let current = current fact in
639
    let z = fact.lookahead in
POTTIER Francois's avatar
POTTIER Francois committed
640
    let i = index current z in
641 642 643 644 645 646 647 648 649 650 651 652
    let m = table.(i) in
    (* We crucially rely on the fact that [M.add] guarantees not to
       change the set if an ``equal'' fact already exists. Thus, a
       later, longer path is ignored in favor of an earlier, shorter
       path. *)
    let m' = M.add fact m in
    m != m' && begin
      incr count;
      table.(i) <- m';
      true
    end

POTTIER Francois's avatar
POTTIER Francois committed
653
  let query current z f =
654 655 656 657 658
    assert (not (Terminal.equal z any));
    (* If the state [current] is solid then the facts that concern it are
       stored in the column [any], and all of them are compatible with [z].
       Otherwise, they are stored in all columns except [any], and only
       those stored in the column [z] are compatible with [z]. *)
659
    let i = index current (if is_solid current then any else z) in
660 661
    let m = table.(i) in
    M.iter f m
662

663 664 665
  let size () =
    !count

666
  let verbose () =
667
    Printf.eprintf "T stores %d facts.\n%!" (size())
668

669 670
end

POTTIER Francois's avatar
POTTIER Francois committed
671 672
(* ------------------------------------------------------------------------ *)

673 674
(* The module [E] is in charge of recording the non-terminal edges that we have
   discovered, or more precisely, the conditions under which these edges can be
POTTIER Francois's avatar
POTTIER Francois committed
675 676 677 678 679 680 681 682 683 684 685 686
   taken.
   
   It maintains a set of quadruples [s, nt, w, z], where such a quadruple means
   that in the state [s], the outgoing edge labeled [nt] can be taken by
   consuming the word [w], under the assumption that the next symbol is [z].

   Again, the terminal symbol [a], given by [W.first w z], plays a role. For
   each quadruple [s, nt, a, z], we store at most one quadruple [s, nt, w, z].
   Thus, internally, we maintain a mapping of [s, nt, a, z] to [w].

   For greater simplicity, we do not allow [z] to be [any] in [register] or
   [query]. Allowing it would complicate things significantly, it seems. *)
687 688 689 690

module E : sig

  (* [register s nt w z] records that, in state [s], the outgoing edge labeled
691
     [nt] can be taken by consuming the word [w], if the next symbol is [z].
POTTIER Francois's avatar
POTTIER Francois committed
692 693
     It returns [true] if this information is new, i.e., if the underlying
     quadruple [s, nt, a, z] is new. The symbol [z] cannot be [any]. *)
694
  val register: Lr1.node -> Nonterminal.t -> W.word -> Terminal.t -> bool
695

POTTIER Francois's avatar
POTTIER Francois committed
696 697 698 699 700 701 702
  (* [query s nt a z] enumerates all words [w] such that, in state [s], the
     outgoing edge labeled [nt] can be taken by consuming the word [w], under
     the assumption that the next symbol is [z], and the first symbol of the
     word [w.z] is [a]. The symbol [a] can be [any]. The symbol [z] cannot be
     [any]. *)
  val query: Lr1.node -> Nonterminal.t -> Terminal.t -> Terminal.t ->
             (W.word -> unit) -> unit
703

704 705 706
  (* [size()] returns the number of edges currently stored in the set. *)
  val size: unit -> int

POTTIER Francois's avatar
POTTIER Francois committed
707
  (* [verbose()] outputs debugging & performance information. *)
708
  val verbose: unit -> unit
709

710 711
end = struct

712 713 714 715 716 717 718 719 720 721
  (* At a high level, we must implement a mapping of [s, nt, a, z] to [w]. In
     practice, we can implement this specification using any combination of
     arrays, hash tables, balanced binary trees, and perfect hashing (i.e.,
     packing several of [s], [nt], [a], [z] in one word.) Here, we choose to
     use an array, indexed by [s], of hash tables, indexed by a key that packs
     [nt], [a], and [z] in one word. According to a quick experiment, the
     final population of the hash table [table.(index s)] seems to be roughly
     [Terminal.n * Trie.size s]. We note that using an initial capacity
     of 0 and relying on the hash table's resizing mechanism has a significant
     cost, which is why we try to guess a good initial capacity. *)
722

723
  module H = Hashtbl
724

POTTIER Francois's avatar
POTTIER Francois committed
725 726
  let table =
    Array.init Lr1.n (fun i ->
727 728 729
      let size = Trie.size i in
      H.create (if size = 1 then 0 else Terminal.n * size)
    )
730 731 732

  let index s =
    Lr1.number s
733

734
  let pack nt a z : int =
POTTIER Francois's avatar
POTTIER Francois committed
735
    (* We rely on the fact that we have at most 256 terminal symbols. *)
736 737 738
    (Nonterminal.n2i nt lsl 16) lor
    (Terminal.t2i a lsl 8) lor
    (Terminal.t2i z)
739

740 741
  let count = ref 0

742
  let register s nt w z =
743
    assert (Terminal.real z);
744
    let i = index s in
745
    let m = table.(i) in
746
    let a = W.first w z in
POTTIER Francois's avatar
POTTIER Francois committed
747
    (* Note that looking at [a] in state [s] cannot cause an error. *)
748
    assert (not (causes_an_error s a));
749 750 751 752
    let key = pack nt a z in
    if H.mem m key then
      false
    else begin
753
      incr count;
754
      H.add m key w;
755 756
      true
    end
757

758
  let rec query s nt a z f =
759
    assert (Terminal.real z);
POTTIER Francois's avatar
POTTIER Francois committed
760 761
    if Terminal.equal a any then begin
      (* If [a] is [any], we query the table for every real symbol [a].
762 763 764 765 766 767
         We can limit ourselves to symbols that do not cause an error
         in state [s]. Those that do certainly do not have an entry;
         see the assertion in [register] above. *)
      foreach_terminal_not_causing_an_error s (fun a ->
        query s nt a z f
      )
POTTIER Francois's avatar
POTTIER Francois committed
768 769 770 771 772 773 774 775
    end
    else begin
      let i = index s in
      let m = table.(i) in
      let key = pack nt a z in
      match H.find m key with
      | w -> f w
      | exception Not_found -> ()
776
    end
777

778 779 780
  let size () =
    !count

781
  let verbose () =
782
    Printf.eprintf "E stores %d edges.\n%!" (size())
783

784 785
end

POTTIER Francois's avatar
POTTIER Francois committed
786 787
(* ------------------------------------------------------------------------ *)

POTTIER Francois's avatar
POTTIER Francois committed
788 789 790 791 792 793 794
(* [new_edge s nt w z] is invoked when we discover that in the state [s], the
   outgoing edge labeled [nt] can be taken by consuming the word [w], under
   the assumption that the next symbol is [z]. We check whether this quadruple
   already exists in the set [E]. If not, then we add it, and we compute its
   consequences, in the form of new facts, which we insert into the priority
   queue for later examination. *)

795
let new_edge s nt w z =
796
  assert (Terminal.real z);
797
  if E.register s nt w z then
798
    let sym = Symbol.N nt in
POTTIER Francois's avatar
POTTIER Francois committed
799 800 801 802
    (* Query [T] for existing facts which could be extended by following
       this newly discovered edge. They must be facts whose current state
       is [s] and whose lookahead assumption is compatible with [a]. For
       each such fact, ... *)
803
    T.query s (W.first w z) (fun fact ->
804
      assert (compatible fact.lookahead (W.first w z));
POTTIER Francois's avatar
POTTIER Francois committed
805
      (* ... try to take one step in the trie along an edge labeled [nt]. *)
806 807
      match Trie.step sym fact.position with
      | position ->
POTTIER Francois's avatar
POTTIER Francois committed
808 809 810 811 812 813
          (* This takes up to a new state whose incoming symbol is [nt].
             Hence, this state is not solid. In order to satisfy invariant 2,
             we must create fact whose lookahead assumption is not [any].
             That's fine, since our lookahead assumption is [z]. In order to
             satisfy invariant 1, we must check that [z] does not cause an
             error in this state. *)
814
          assert (not (is_solid (Trie.current position)));
815
          if not (causes_an_error (Trie.current position) z) then
POTTIER Francois's avatar
POTTIER Francois committed
816 817
            let word = W.append fact.word w in
            add { position; word; lookahead = z }
818
      | exception Not_found ->
POTTIER Francois's avatar
POTTIER Francois committed
819 820 821
          (* Could not take a step in the trie. This means this branch
             leads nowhere of interest, and was pruned when the trie
             was constructed. *)
822
          ()
823
    )
824

POTTIER Francois's avatar
POTTIER Francois committed
825 826
(* ------------------------------------------------------------------------ *)

POTTIER Francois's avatar
POTTIER Francois committed
827 828
(* [new_fact fact] is invoked when we discover a new fact (i.e., one that was
   not previously known). It studies the consequences of this fact. These
829 830 831
   consequences are of two kinds:

   - As in Dijkstra's algorithm, the new fact can be viewed as a newly
POTTIER Francois's avatar
POTTIER Francois committed
832 833 834 835 836 837 838 839 840
     discovered vertex. We study its (currently known) outgoing edges,
     and enqueue new facts in the priority queue.

   - Sometimes, a fact can also be viewed as a newly discovered edge. This is
     the case when the word that took us from [fact.source] to [fact.current]
     represents a production of the grammar and [fact.current] is willing to
     reduce this production. We record the existence of this edge, and
     re-inspect any previously discovered vertices which are interested in
     this outgoing edge. *)
841

POTTIER Francois's avatar
POTTIER Francois committed
842
let new_fact fact =
843

POTTIER Francois's avatar
POTTIER Francois committed
844
  let current = current fact in
845

POTTIER Francois's avatar
POTTIER Francois committed
846 847 848
  (* 1. View [fact] as a vertex. Examine the transitions out of [current].
     For every transition labeled by a symbol [sym] and into a state
     [target], ... *)
849
  
POTTIER Francois's avatar
POTTIER Francois committed
850 851 852
  Lr1.transitions current |> SymbolMap.iter (fun sym target ->
    (* ... try to follow this transition in the trie [fact.position],
       down to a child which we call [position]. *)
853
    match Trie.step sym fact.position, sym with
POTTIER Francois's avatar
POTTIER Francois committed
854 855 856 857 858 859 860

    | exception Not_found ->

        (* Could not take a step in the trie. This means this transition
           leads nowhere of interest. *)
        ()

861
    | position, Symbol.T t ->
POTTIER Francois's avatar
POTTIER Francois committed
862 863 864 865 866 867
          
        (* 1a. The transition exists in the trie, and [sym] is in fact a
           terminal symbol [t]. We note that [t] cannot be the [error] token,
           because the trie does not have any edges labeled [error]. *)
        assert (Lr1.Node.compare (Trie.current position) target = 0);
        assert (is_solid target);
868
        assert (non_error t);
869

POTTIER Francois's avatar
POTTIER Francois committed
870 871 872 873 874 875 876 877 878 879 880
        (* If the lookahead assumption [fact.lookahead] is compatible with
           [t], then we derive a new fact, where one more edge has been taken,
           and enqueue this new fact for later examination. *)
        
        (* The state [target] is solid, i.e., its incoming symbol is terminal.
           This state is always entered without consideration for the next
           lookahead symbol. Thus, we can use [any] as the lookahead assumption
           in the new fact that we produce. If we did not have [any], we would
           have to produce one fact for every possible lookahead symbol. *)

        if compatible fact.lookahead t then
881
          let word = W.append fact.word (W.singleton t) in
882
          add { position; word; lookahead = any }
883

884
    | position, Symbol.N nt ->
885

POTTIER Francois's avatar
POTTIER Francois committed
886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904
        (* 1b. The transition exists in the trie, and [sym] is in fact a
           nonterminal symbol [nt]. *)
         assert (Lr1.Node.compare (Trie.current position) target = 0);
         assert (not (is_solid target));

        (* We need to know how this nonterminal edge can be taken. We query
           [E] for a word [w] that allows us to take this edge. In general,
           the answer depends on the terminal symbol [z] that comes *after*
           this word: we try all such symbols. We must make sure that the
           first symbol of the word [w.z] satisfies the lookahead assumption
           [fact.lookahead]; this is ensured by passing this information to
           [E.query]. *)

        (* It could be the case that, due to a default reduction, the answer
           to our query does not depend on [z], and we are wasting work.
           However, allowing [z] to be [any] in [E.query], and taking 
           advantage of this to increase performance, seems difficult. *)

        foreach_terminal_not_causing_an_error target (fun z ->
POTTIER Francois's avatar
POTTIER Francois committed
905
          E.query current nt fact.lookahead z (fun w ->
906
            assert (compatible fact.lookahead (W.first w z));
POTTIER Francois's avatar
POTTIER Francois committed
907 908
            let word = W.append fact.word w in
            add { position; word; lookahead = z }
909 910
          )
        )
911

POTTIER Francois's avatar
POTTIER Francois committed
912
  );
913 914

  (* 2. View [fact] as a possible edge. This is possible if the path from
POTTIER Francois's avatar
POTTIER Francois committed
915 916
     [fact.source] to the [current] state represents a production [prod] and
     [current] is willing to reduce this production. Then, reducing [prod]
917 918
     takes us all the way back to [fact.source]. Thus, this production gives
     rise to an edge labeled [nt] -- the left-hand side of [prod] -- out of
POTTIER Francois's avatar
POTTIER Francois committed
919
     [fact.source]. *)
920

POTTIER Francois's avatar
POTTIER Francois committed
921 922 923 924 925 926 927 928 929 930
  let z = fact.lookahead in
  if not (Terminal.equal z any) then begin

    (* 2a. The lookahead assumption [z] is a real terminal symbol. We check
       whether [current] is willing to reduce some production [prod] on [z],
       and whether the sub-trie [fact.position] accepts [prod], which means
       that this reduction takes us back to the root of the trie. If so, we
       have discovered a new edge. *)

    match has_reduction current z with
931
    | Some prod when Trie.accepts prod fact.position ->
POTTIER Francois's avatar
POTTIER Francois committed
932
        new_edge (source fact) (Production.nt prod) fact.word z
933 934
    | _ ->
        ()
POTTIER Francois's avatar
POTTIER Francois committed
935

936 937
  end
  else begin
POTTIER Francois's avatar
POTTIER Francois committed
938 939 940 941 942

    (* 2b. The lookahead assumption is [any]. We must consider every pair
       [prod, z] such that the [current] state can reduce [prod] on [z]
       and [fact.position] accepts [prod]. *)

943 944 945
    match Invariant.has_default_reduction current with
    | Some (prod, _) ->
        if Trie.accepts prod fact.position then
POTTIER Francois's avatar
POTTIER Francois committed
946 947
          (* [new_edge] does not accept [any] as its 4th parameter, so we
             must iterate over all terminal symbols. *)
948
          foreach_terminal (fun z ->
POTTIER Francois's avatar
POTTIER Francois committed
949
            new_edge (source fact) (Production.nt prod) fact.word z
950 951 952
          )
    | None ->
       TerminalMap.iter (fun z prods ->
953
         if non_error z then
954 955
           let prod = Misc.single prods in
           if Trie.accepts prod fact.position then
POTTIER Francois's avatar
POTTIER Francois committed
956
             new_edge (source fact) (Production.nt prod) fact.word z
957
       ) (Lr1.reductions current)
POTTIER Francois's avatar
POTTIER Francois committed
958

959
  end
960

POTTIER Francois's avatar
POTTIER Francois committed
961 962
(* ------------------------------------------------------------------------ *)

POTTIER Francois's avatar
POTTIER Francois committed
963
(* The main loop of the algorithm. *)
964

965 966 967 968 969
(* [level] is the length of [fact.word] for the facts that we are examining
   at the moment. [extracted] counts how many facts we have extracted out of
   the priority queue. [considered] counts how many of these were found to
   be new, and subsequently passed to [new_fact]. *)

POTTIER Francois's avatar
POTTIER Francois committed
970 971
let level, extracted, considered =
  ref 0, ref 0, ref 0
POTTIER Francois's avatar
POTTIER Francois committed
972

POTTIER Francois's avatar
POTTIER Francois committed
973
let done_with_level () =
974 975 976 977 978 979 980
  Printf.eprintf "Done with level %d.\n" !level;
  W.verbose();
  T.verbose();
  E.verbose();
  Printf.eprintf "Q stores %d facts.\n" (Q.cardinal q);
  Printf.eprintf "%d facts extracted out of Q, of which %d considered.\n%!"
    !extracted !considered
981

POTTIER Francois's avatar
POTTIER Francois committed
982
let () =
POTTIER Francois's avatar
POTTIER Francois committed
983 984 985
  Q.repeat q (fun fact ->
    incr extracted;
    if T.register fact then begin
986
      if X.verbose && W.length fact.word > !level then begin
POTTIER Francois's avatar
POTTIER Francois committed
987 988 989 990 991 992 993
        done_with_level();
        level := W.length fact.word;
      end;
      incr considered;
      new_fact fact
    end
  );
994 995
  if X.verbose then
    done_with_level();
POTTIER Francois's avatar
POTTIER Francois committed
996
  Time.tick "Running LRijkstra"
997

998 999
(* ------------------------------------------------------------------------ *)

1000
(* The following code validates the fact that an error can be triggered in
1001 1002 1003 1004
   state [s'] by beginning at the start symbol [nt] and reading the
   sequence of terminal symbols [w]. We use this for debugging purposes.
   Furthermore, this gives us a list of spurious reductions, which we use
   to produce a comment. *)
1005 1006

let fail msg =
1007
  Printf.eprintf "LRijkstra: internal error: %s.\n%!" msg;
1008
  exit 1
1009

1010
let validate nt s' w : ReferenceInterpreter.target =
1011
  let open ReferenceInterpreter in
1012
  match
1013
    check_error_path nt (W.elements w)
1014 1015 1016 1017 1018 1019 1020
  with
  | OInputReadPastEnd ->
      fail "input was read past its end"
  | OInputNotFullyConsumed ->
      fail "input was not fully consumed"
  | OUnexpectedAccept ->
      fail "input was unexpectedly accepted"
1021 1022 1023 1024 1025 1026 1027 1028 1029
  | OK ((state, _) as target) ->
      if Lr1.Node.compare state s' <> 0 then
        fail (
          Printf.sprintf "error occurred in state %d instead of %d"
            (Lr1.number state)
            (Lr1.number s')
        )
      else
        target
1030 1031 1032

(* ------------------------------------------------------------------------ *)

1033 1034 1035 1036 1037 1038 1039
(* We now wish to determine, given a state [s'] and a terminal symbol [z], a
   minimal path that takes us from some entry state to state [s'] with [z] as
   the next (unconsumed) symbol. *)

(* This can be formulated as a search for a shortest path in a graph. The
   graph is not just the automaton, though. It is a (much) larger graph whose
   vertices are pairs [s, z] and whose edges are obtained by querying the
1040 1041 1042
   module [E] above. For this purpose, we use Dijkstra's algorithm,
   unmodified. Experiments show that the running time of this phase is
   typically 10x shorter than the running time of the main loop above. *)
1043

1044
module A = Astar.Make(struct
1045

1046 1047 1048
  (* A vertex is a pair [s, z], where [z] is a real terminal symbol. *)
  type node =
      Lr1.node * Terminal.t
1049

1050 1051
  let equal (s'1, z1) (s'2, z2) =
    Lr1.Node.compare s'1 s'2 = 0 && Terminal.compare z1 z2 = 0
1052

1053 1054
  let hash (s, z) =
    Hashtbl.hash (Lr1.number s, z)
1055

1056 1057 1058
  (* An edge is labeled with a word. *)
  type label =
    W.word
1059

1060 1061 1062 1063 1064 1065 1066
  (* We search forward from every [s, z], where [s] is an initial state. *)
  let sources f =
    foreach_terminal (fun z ->
      ProductionMap.iter (fun _ s ->
        f (s, z)
      ) Lr1.entry
    )
1067

1068 1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093 1094
  (* The successors of [s, z] are defined as follows. *)
  let successors (s, z) edge =
    assert (Terminal.real z);
    (* For every transition out of [s], labeled [sym], leading to [s']... *)
    Lr1.transitions s |> SymbolMap.iter (fun sym s' ->
      match sym with
      | Symbol.T t ->
          if Terminal.equal z t then
            (* If [sym] is the terminal symbol [z], then this transition
               matches our lookahead assumption, so we can take it. For
               every [z'], we have an edge to [s', z'], labeled with the
               singleton word [z]. *)
            let w = W.singleton z in
            foreach_terminal (fun z' ->
              edge w 1 (s', z')
            )
      | Symbol.N nt ->
          (* If [sym] is a nonterminal symbol [nt], then we query [E]
             in order to find out which (minimal) words [w] allow us
             to take this transition. We must again try every [z'],
             and must respect the constraint that the first symbol
             of the word [w.z'] is [z]. For every [z'] and [w] that
             fulfill these requirements, we have an edge to [s', z'],
             labeled with the word [w]. *)
         foreach_terminal (fun z' ->
           E.query s nt z z' (fun w ->
             edge w (W.length w) (s', z')
1095
           )
1096 1097
         )
    )
1098

1099 1100 1101 1102 1103 1104 1105 1106 1107
  (* Algorithm A*, used with a zero estimate, is Dijkstra's algorithm.
     We have experimented with a non-zero estimate, but the performance
     increase was minimal. *)
  let estimate _ =
    0

end)

(* ------------------------------------------------------------------------ *)
1108

1109 1110
(* [explored] counts how many graph nodes we have discovered during the
   search. *)
1111