Commit 5f44f7db authored by POTTIER Francois's avatar POTTIER Francois

Re-instated [ErrorReporting] as part of the calc-inspection demo,

which needs it. This module still needs cleaning up.
parent 96ad8c30
module Make
(I : MenhirLib.IncrementalEngine.EVERYTHING)
(User : sig
(* In order to submit artificial tokens to the parser, we need a function
that converts a terminal symbol to a token. Unfortunately, we cannot
(in general) auto-generate this code, because it requires making up
semantic values of arbitrary OCaml types. *)
val terminal2token: _ I.terminal -> I.token
end)
= struct
open MenhirLib.General
open I
open User
(* ------------------------------------------------------------------------ *)
(* Explanations. *)
type explanation = {
item: item;
past: (xsymbol * Lexing.position * Lexing.position) list
}
let item explanation =
explanation.item
let past explanation =
explanation.past
let future explanation =
let prod, index = explanation.item in
let rhs = rhs prod in
drop index rhs
let goal explanation =
let prod, _ = explanation.item in
lhs prod
(* ------------------------------------------------------------------------ *)
(* [items_current env] assumes that [env] is not an initial state (which
implies that the stack is non-empty). Under this assumption, it extracts
the automaton's current state, i.e., the LR(1) state found in the top
stack cell. It then goes through [items] so as to obtain the LR(0) items
associated with this state. *)
let items_current env : item list =
(* Get the current state. *)
match Lazy.force (stack env) with
| Nil ->
(* If we get here, then the stack is empty, which means the parser
is in an initial state. This should not happen. *)
invalid_arg "items_current" (* TEMPORARY it DOES happen! *)
| Cons (Element (current, _, _, _), _) ->
(* Extract the current state out of the top stack element, and
convert it to a set of LR(0) items. Returning a set of items
instead of an ['a lr1state] is convenient; returning [current]
would require wrapping it in an existential type. *)
items current
(* [is_shift_item t item] determines whether [item] justifies a shift
transition along the terminal symbol [t]. *)
let is_shift_item (t : _ terminal) (prod, index) : bool =
let rhs = rhs prod in
let length = List.length rhs in
assert (0 < index && index <= length);
(* We test that there is one symbol after the bullet and this symbol
is [t] or can generate a word that begins with [t]. (Note that we
don't need to worry about the case where this symbol is nullable
and [t] is generated by the following symbol. In that situation,
we would have to reduce before we can shift [t].) *)
index < length && xfirst (List.nth rhs index) t
let compare_explanations x1 x2 =
let c = compare_items x1.item x2.item in
(* TEMPORARY checking that if [c] is 0 then the positions are the same *)
assert (
c <> 0 || List.for_all2 (fun (_, start1, end1) (_, start2, end2) ->
start1.Lexing.pos_cnum = start2.Lexing.pos_cnum &&
end1.Lexing.pos_cnum = end2.Lexing.pos_cnum
) x1.past x2.past
);
c
(* [marry past stack] TEMPORARY comment *)
let rec marry past stack =
match past, stack with
| [], _ ->
[]
| symbol :: past, lazy (Cons (Element (s, _, startp, endp), stack)) ->
assert (compare_symbols symbol (X (incoming_symbol s)) = 0);
(symbol, startp, endp) :: marry past stack
| _ :: _, lazy Nil ->
assert false
(* [accumulate t env explanations] is called if the parser decides to shift
the test token [t]. The parameter [env] describes the parser configuration
before it shifts this token. (Some reductions have taken place.) We use the
shift items found in [env] to produce new explanations. *)
let accumulate (t : _ terminal) env explanations =
(* The parser is about to shift, which means it is willing to
consume the terminal symbol [t]. In the state before the
transition, look at the items that justify shifting [t].
We view these items as explanations: they explain what
we have read and what we expect to read. *)
let stack = stack env in
List.fold_left (fun explanations item ->
if is_shift_item t item then
let prod, index = item in
let rhs = rhs prod in
{
item = item;
past = List.rev (marry (List.rev (take index rhs)) stack)
} :: explanations
else
explanations
) explanations (items_current env)
(* TEMPORARY [env] may be an initial state!
violating [item_current]'s precondition *)
(* [investigate pos checkpoint] assumes that [checkpoint] is of the form
[InputNeeded _]. For every terminal symbol [t], it investigates
how the parser reacts when fed the symbol [t], and returns a list
of explanations. The position [pos] is where a syntax error was
detected; it is used when manufacturing dummy tokens. This is
important because the position of the dummy token may end up in
the explanations that we produce. *)
let investigate pos (checkpoint : _ checkpoint) : explanation list =
weed compare_explanations (
foreach_terminal_but_error (fun symbol explanations ->
match symbol with
| X (N _) -> assert false
| X (T t) ->
(* Build a dummy token for the terminal symbol [t]. *)
let token = (terminal2token t, pos, pos) in
(* Submit it to the parser. Accumulate explanations. *)
let checkpoint = offer checkpoint token in
I.loop_test (accumulate t) checkpoint explanations
) []
)
(* We drive the parser in the usual way, but records the last [InputNeeded]
checkpoint. If a syntax error is detected, we go back to this checkpoint
and analyze it in order to produce a meaningful diagnostic. *)
exception Error of (Lexing.position * Lexing.position) * explanation list
let entry (start : 'a I.checkpoint) lexer lexbuf =
let fail (inputneeded : 'a I.checkpoint) (checkpoint : 'a I.checkpoint) =
(* The parser signals a syntax error. Note the position of the
problematic token, which is useful. Then, go back to the
last [InputNeeded] checkpoint and investigate. *)
match checkpoint with
| HandlingError env ->
let (startp, _) as positions = positions env in
raise (Error (positions, investigate startp inputneeded))
| _ ->
assert false
in
I.loop_handle_undo
(fun v -> v)
fail
(lexer_lexbuf_to_supplier lexer lexbuf)
start
(* TEMPORARY could also publish a list of the terminal symbols that
do not cause an error *)
end
(* This module needs cleaning up. It is supposed to automatically
produce a syntax error message, based on the current state and
stack. *)
module Make
(I : MenhirLib.IncrementalEngine.EVERYTHING)
(User : sig
(* In order to submit artificial tokens to the parser, we need a function
that converts a terminal symbol to a token. Unfortunately, we cannot
(in general) auto-generate this code, because it requires making up
semantic values of arbitrary OCaml types. *)
val terminal2token: _ I.terminal -> I.token
end)
: sig
open I
(* An explanation is a description of what the parser has recognized in the
recent past and what it expects next. More precisely, an explanation is
an LR(0) item, enriched with positions. Indeed, the past (the first half
of the item's right-hand side, up to the bullet) corresponds to a part of
the input that has been read already, so it can be annotated with
positions. *)
type explanation
(* The LR(0) item. *)
val item: explanation -> item
(* The past. This is a non-empty sequence of (terminal and non-terminal)
symbols, each of which corresponds to a range of the input file. These
symbols correspond to the first half (up to the bullet) of the item's
right-hand side. In short, they represent what (we think) we have
recognized in the recent past. *)
(* It is worth noting that, when an error occurs, we produce multiple
explanations, which may have different pasts. Indeed, not only may
these pasts have different lengths (one may be a suffix of another),
but two pasts can in fact be incomparable. Indeed, different choices
of the lookahead token may cause different reductions, hence different
interpretations of what has been read in the past. *)
val past: explanation -> (xsymbol * Lexing.position * Lexing.position) list
(* The future. This is a non-empty sequence of (terminal and non-terminal)
symbols. These symbols correspond to the second half (after the bullet)
of the item's right-hand side. In short, they represent what we expect
to recognize in the future, if this item is a good prediction. *)
(* This information can be computed from [item]. This function is provided
only for convenience. *)
val future: explanation -> xsymbol list
(* A goal. This is a non-terminal symbol. It is the item's left-hand side.
In short, it represents the reduction that we will be able to perform if
we successfully recognize this future. *)
(* This information can be computed from [item]. This function is provided
only for convenience. *)
val goal: explanation -> xsymbol
(* TEMPORARY *)
(* We build lists of explanations. These explanations may originate in
distinct LR(1) states. They may have different pasts, because *)
exception Error of (Lexing.position * Lexing.position) * explanation list
(* TEMPORARY *)
val entry: 'a I.checkpoint -> (Lexing.lexbuf -> token) -> Lexing.lexbuf -> 'a
end
......@@ -26,4 +26,7 @@ clean:
test: all
@echo "The following command should print 42:"
echo "(1 + 2 * 10) * 2" | ./$(MAIN).native
@echo "The following command should print an error message:"
echo "(1 + 2 * 10) * )" | ./$(MAIN).native
@echo "The following command should print an error message:"
echo "(1 + 2 * 10))" | ./$(MAIN).native
......@@ -9,11 +9,11 @@ module P =
(Parser.MenhirInterpreter)
(CalcPrinters)
(* Instantiate [MenhirLib.ErrorReporting] for our parser. This requires
(* Instantiate [ErrorReporting] for our parser. This requires
providing a few functions -- see [CalcErrorReporting]. *)
module E =
MenhirLib.ErrorReporting.Make
ErrorReporting.Make
(Parser.MenhirInterpreter)
(CalcErrorReporting)
......
Markdown is supported
0%
or
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment