##  Copyright 2009-2016 Inria
##
## This file is part of the PaMPA software package for parallel
## mesh partitioning and adaptation.
##
## PaMPA is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 3 of the License, or
## any later version.
## 
## PaMPA is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
## 
## In this respect, the user's attention is drawn to the risks associated
## with loading, using, modifying and/or developing or reproducing the
## software by the user in light of its specific status of free software,
## that may mean that it is complicated to manipulate, and that also
## therefore means that it is reserved for developers and experienced
## professionals having in-depth computer knowledge. Users are therefore
## encouraged to load and test the software's suitability as regards
## their requirements in conditions enabling the security of their
## systems and/or data to be ensured and, more generally, to use and
## operate it in the same conditions as regards security.
## 
## The fact that you are presently reading this means that you have had
## knowledge of the GPLv3 license and that you accept its terms.
##
#############################################################
##
##    \file        libpampa/CMakeLists.txt
##
##    \authors     Cedric Lachat
##
##    \brief       This file is a part of the configuration
##                 to build PaMPA with CMake
##
##    \date        Version 1.0: from: 31 May 2011
##                              to:   30 Sep 2016
##                 Version 2.0: from:  7 Oct 2016
##                              to:   12 May 2017
##
#############################################################

include_directories(${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR})


########################
#      dummysizes      #
########################
add_executable(dummysizes dummysizes.c)



########################
#     libpampa    #
########################
if (OLD_CMAKE)
  # Generate pampa.h
  add_custom_command(OUTPUT pampa.h
    COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/library.h ${CMAKE_CURRENT_BINARY_DIR}
    COMMAND ./dummysizes library.h pampa.h DEPENDS dummysizes
    DEPENDS library.h)

  if (FORTRAN_INTERFACE)
    # Generate pampaf_common.h
    add_custom_command(OUTPUT pampaf_common.h
      COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/library_commonf.h ${CMAKE_CURRENT_BINARY_DIR}
      COMMAND ./dummysizes library_commonf.h pampaf_common.h DEPENDS dummysizes
      DEPENDS library_commonf.h)

    ## Generate pampaf.h
    add_custom_command(OUTPUT pampaf.h
      COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/libraryf.h ${CMAKE_CURRENT_BINARY_DIR}/libraryf.h
      COMMAND ./dummysizes libraryf.h pampaf.h DEPENDS dummysizes
      DEPENDS libraryf.h)
  endif (FORTRAN_INTERFACE)
else (OLD_CMAKE)
  # Generate pampa.h
  add_custom_command(OUTPUT pampa.h
    COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/library.h ${CMAKE_CURRENT_BINARY_DIR}
    COMMAND $<TARGET_FILE:dummysizes> library.h pampa.h DEPENDS dummysizes
    DEPENDS library.h)

  if (SCM_VERSIONS)
    # Generate versions_ext.h
    add_custom_command(OUTPUT versions_ext.h
      COMMAND ${CMAKE_MODULE_PATH}/software_version.sh ${VERSIONS_EXT_ARGS}
      DEPENDS ${VERSIONS_EXT_DEPS})
    file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/version.cmake
      "MACRO (TODAY RESULT)
      IF (WIN32)
        EXECUTE_PROCESS(COMMAND \"cmd\" \" /C date /T\" OUTPUT_VARIABLE \${RESULT})
        string(REGEX REPLACE \"(..)/(..)/..(..).*\" \"\\\\1/\\\\2/\\\\3\" \${RESULT} \${\${RESULT}})
      ELSEIF(UNIX)
        EXECUTE_PROCESS(COMMAND \"date\" \"+%d/%m/%Y\" OUTPUT_VARIABLE \${RESULT})
        string(REGEX REPLACE \"(..)/(..)/..(..).*\" \"\\\\1/\\\\2/\\\\3\" \${RESULT} \${\${RESULT}})
      ELSE (WIN32)
        MESSAGE(SEND_ERROR \"date not implemented\")
        SET(${RESULT} 000000)
      ENDIF (WIN32)
    ENDMACRO (TODAY)
      
    TODAY(DATE)
    CONFIGURE_FILE(\${SRC} \${DST} @ONLY)
    ")

    add_custom_target(
      version
      ${CMAKE_COMMAND}
      -D SRC=${CMAKE_CURRENT_SOURCE_DIR}/core_version.h.in
      -D DST=${CMAKE_CURRENT_BINARY_DIR}/version.h
      -P ${CMAKE_CURRENT_BINARY_DIR}/version.cmake
      )
    add_custom_command(TARGET version POST_BUILD
      COMMAND ${CMAKE_MODULE_PATH}/software_version2.sh
      ${CMAKE_CURRENT_BINARY_DIR}/version.h
      ${CMAKE_CURRENT_SOURCE_DIR}/version.h PAMPA ${PAMPA_SOURCE_DIR}
      )
  endif()



  if (FORTRAN_INTERFACE)
    # Generate pampaf_common.h
    add_custom_command(OUTPUT pampaf_common.h
      COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/library_commonf.h ${CMAKE_CURRENT_BINARY_DIR}
      COMMAND $<TARGET_FILE:dummysizes> library_commonf.h pampaf_common.h DEPENDS dummysizes
      DEPENDS library_commonf.h)

    ## Generate pampaf.h
    add_custom_command(OUTPUT pampaf.h
      COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/libraryf.h ${CMAKE_CURRENT_BINARY_DIR}/libraryf.h
      COMMAND $<TARGET_FILE:dummysizes> libraryf.h pampaf.h DEPENDS dummysizes
      DEPENDS libraryf.h)
  endif (FORTRAN_INTERFACE)
endif (OLD_CMAKE)

# Sources to build libpampa

set(ADAPT_C_SOURCES
  pampa.h
  dmesh_adapt_coarsen.c
  dmesh_adapt_coarsen_grow.c
  dmesh_adapt_common.h
  dmesh_adapt_common.c
  dmesh_adapt_graph_grow.c
  dmesh_adapt_mesh_grow.c
  dmesh_adapt_geompart.c
  dmesh_adapt_part.c
  dmesh_adapt.h
  dmesh_band.c
  dmesh_grow.c
  dmesh_rebuild.c
  dmesh_rebuild.h
  dmesh_zone_dist.c
  dmesh_zone_dist.h
  library_dmesh_adapt.c
  library_dmesh_band.c
  library_mesh_induce_multiple.c
  library_mesh_rebuild.c
  mesh_induce_multiple.c
  mesh_induce_multiple.h
  mesh_per_build.c
  mesh_rebuild.c
  mesh_rebuild.h
  )

set(PAMPA_C_SOURCES
  arch.h
  pampa.h
  comm.c
  common_integer.c
  common_file.c
  common_file_compress.c
  common_file_uncompress.c
  common_memory.c
  dmesh.c
  dmesh_allreduce.c
  dmesh_allreduce.h
  dmesh_build.c
  dmesh_check.c
  dmesh_gather_induce_multiple.c
  dmesh_gather_induce_multiple.h
  dmesh_ghst.c
  dmesh_io_load.c
  dmesh_io_load.h
  dmesh_io_mesh_save.c
  dmesh_io_save.c
  dmesh_io_save.h
  dmesh_iter.c
  dmesh_iter.h
  dmesh_halo.c
  dmesh_mat.c
  dmesh_overlap.c
  dmesh_overlap.h
  dmesh_redist.c
  dmesh_redist.h
  dmesh_save.c
  dmesh_scatter.c
  dmesh_values.c
  dsmesh.c
  dsmesh.h
  dsmesh_build.c
  dsmesh_dmesh.c
  dsmesh_dmesh.h
  dsmesh_halo.c
  dsmesh_halo.h
  dsmesh_values.c
  dvalues.c
  dvalues.h
  library_av_iter.c
  library_dmesh.c
  library_dmesh_build.c
  library_dmesh_check.c
  library_dmesh_data.c
  library_dmesh_dgraph.c
  library_dmesh_gather.c
  library_dmesh_gather_induce_multiple.c
  library_dmesh_halo.c
  library_dmesh_iter.c
  library_dmesh_mat.c
  library_dmesh_io_load.c
  library_dmesh_io_save.c
  library_dmesh_io_mesh_save.c
  library_dmesh_save.c
  library_dmesh_scatter.c
  library_dmesh_values.c
  library_iter.c
  library_mesh.c
  library_mesh_build.c
  library_mesh_check.c
  library_mesh_create.c
  library_mesh_data.c
  library_mesh_io_load.c
  library_mesh_io_mesh_save.c
  library_mesh_io_surface_save.c
  library_mesh_io_save.c
  library_mesh_iter.c
  library_mesh_values.c
  library_smesh.c
  library_smesh_build.c
  library_smesh_data.c
  library_smesh_io_save.c
  library_smesh_mesh.c
  library_smesh_values.c
  #library_topo_io_load.c
  library_versions.c
  mesh.c
  mesh_build.c
  mesh_check.c
  mesh_create.c
  #mesh_coarsen.c
  #mesh_coarsen.h
  mesh_io_load.c
  mesh_io_load.h
  mesh_io_mesh_save.c
  mesh_io_surface_save.c
  mesh_io_save.c
  mesh_iter.c
  mesh_values.c
  smesh.c
  smesh_build.c
  smesh_io_save.c
  smesh_mesh.c
  smesh_mesh.h
  smesh_values.c
  strat.h
  values.c
  values.h)
  
if (PAMPA_MULTILEVEL)
  list(APPEND PAMPA_C_SOURCES
  library_mdmesh.c
  library_mdmesh_coar_level_build.c
  library_mdmesh_dmesh_data.c
  library_mdmesh_iter.c
  library_mdmesh_level.c
  library_mdmesh_redist.c
  mdmesh.c
  mdmesh_coar_level_build.c
  mdmesh_coar_level_build.h
  mdmesh_iter.c
  mdmesh_level.c
  mdmesh_mesh_levels.c
  mdmesh_redist.c)
endif ()

if (SCM_VERSIONS)
  list (APPEND PAMPA_C_SOURCES
    version.h
    versions_ext.h)
endif ()
if (PTSCOTCH)
  list (APPEND PAMPA_C_SOURCES
  	dgraph_graph.c
  	dgraph_graph.h
  	dmesh_dgraph.c
  	dmesh_dgraph.h
  	dmesh_graph.c
  	dmesh_graph.h
  	dmesh_map.c
  	library_dmesh_map.c
  	library_dmesh_redist.c
  	library_mesh_map.c
  	library_parser.c
  	mesh_graph.c
  	mesh_graph.h
  	mesh_map.c)
endif ()

if (FORTRAN_INTERFACE)
  set(PAMPA_FORTRAN_SOURCES
    dmesh_f.c
    library_dmesh_values_f.c
    library_mesh_values_f.c
    pampaf.h
    pampaf_common.h
    library_dmesh.F90
    library_dmesh_build.F90
    library_dmesh_check.F90
    library_dmesh_data.F90
    library_dmesh_gather.F90
    library_dmesh_halo.F90
    library_dmesh_iter.F90
    library_dmesh_mat.F90
    library_dmesh_redist.F90
    library_dmesh_scatter_f.c
    library_dmesh_scatter.F90
    library_dmesh_values.F90
    library_iter.F90
    library_mesh.F90
    library_mesh_build.F90
    library_mesh_check.F90
    library_mesh_data.F90
    library_mesh_iter.F90
    library_mesh_values.F90
    library_types.F90
    library.F90)
  if (PTSCOTCH)
    list (APPEND PAMPA_FORTRAN_SOURCES
      library_dmesh_map.F90
      library_mesh_map.F90
      library_parser.F90
      )
  endif ()
else (FORTRAN_INTERFACE)
  set (PAMPA_FORTRAN_SOURCES)
endif (FORTRAN_INTERFACE)



add_library(
  pampa
  ${PAMPA_C_SOURCES}
  ${PAMPA_FORTRAN_SOURCES})
if (SCM_VERSIONS)
  add_dependencies(pampa
    version)
endif ()

add_library(
  pampaerr
  pampa.h
  library_error.c)

add_library(
  pampaerrexit
  pampa.h
  library_error_exit.c)


set_target_properties(pampa PROPERTIES VERSION
  ${PAMPA_VERSION}.${PAMPA_RELEASE}.${PAMPA_PATCHLEVEL})

if (OLD_CMAKE)
  if (PAMPA_BUILD_ALONE)
    add_custom_command(TARGET pampa POST_BUILD
      COMMAND ${CMAKE_COMMAND} -E copy libpampa.a ${PAMPA_SOURCE_DIR}/pampa/lib
      )
    add_custom_command(TARGET pampaerr POST_BUILD
      COMMAND ${CMAKE_COMMAND} -E copy libpampaerr.a ${PAMPA_SOURCE_DIR}/pampa/lib
      )
    add_custom_command(TARGET pampaerrexit POST_BUILD
      COMMAND ${CMAKE_COMMAND} -E copy libpampaerrexit.a ${PAMPA_SOURCE_DIR}/pampa/lib
      )
  endif ()
else (OLD_CMAKE)
  if (PAMPA_BUILD_ALONE)
    add_custom_command(TARGET pampa POST_BUILD
      COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:pampa> ${PAMPA_SOURCE_DIR}/pampa/lib
      )
    add_custom_command(TARGET pampaerr POST_BUILD
      COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:pampaerr> ${PAMPA_SOURCE_DIR}/pampa/lib
      )
    add_custom_command(TARGET pampaerrexit POST_BUILD
      COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:pampaerrexit> ${PAMPA_SOURCE_DIR}/pampa/lib
      )
  endif ()
endif (OLD_CMAKE)
if (FORTRAN_INTERFACE)
  add_custom_command(TARGET pampa POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy ${PROJECT_BINARY_DIR}/MOD/pampa.mod ${PAMPA_SOURCE_DIR}/pampa/include
    )
endif (FORTRAN_INTERFACE)

# Specify where libpampa and include files will be installed
if (BUILD_SHARED_LIBS)
install(TARGETS pampa LIBRARY DESTINATION lib)
install(TARGETS pampaerr LIBRARY DESTINATION lib)
install(TARGETS pampaerrexit LIBRARY DESTINATION lib)
else ()
install(TARGETS pampa ARCHIVE DESTINATION lib)
install(TARGETS pampaerr ARCHIVE DESTINATION lib)
install(TARGETS pampaerrexit ARCHIVE DESTINATION lib)
endif ()
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/pampa.h
  DESTINATION include)
if (FORTRAN_INTERFACE)
  install(FILES ${CMAKE_CURRENT_BINARY_DIR}/pampaf.h ${PROJECT_BINARY_DIR}/MOD/pampa.mod DESTINATION include)
endif (FORTRAN_INTERFACE)